OCaml

OCaml
Date de première version	1987 (CAML), 1996 (OCaml)
Paradigme	Multiparadigme : impérative, fonctionnelle, orientée objet
Développeur	Inria
Dernière version	5.2.0 (13 mai 2024)
Typage	Fort, statique
Dialectes	JoCaml, Fresh OCaml, GCaml, MetaOCaml, OCamlDuce, OcamlP3L
Influencé par	ML
A influencé	F#, Rust, OPA, Scala
Écrit en	OCaml et C
Système d'exploitation	Multiplate-forme
Licence	LGPL 2.1
Site web	ocaml.org
Extension de fichier	ml et mli

OCaml, anciennement connu sous le nom d'Objective Caml, est l'implémentation la plus avancée du langage de programmation Caml, créé par Xavier Leroy, Jérôme Vouillon, Damien Doligez (en), Didier Rémy et leurs collaborateurs en 1996. Ce langage, de la famille des langages ML, est un projet open source dirigé et maintenu essentiellement par l'Inria.

OCaml est le successeur de Caml Light, auquel il a ajouté entre autres une couche de programmation objet. L'acronyme CAML provient de Categorical Abstract Machine Language, un modèle de machine abstraite qui n'est cependant plus utilisé dans les versions récentes de OCaml.

Portable et performant, OCaml est utilisé dans des projets aussi divers que le logiciel de synchronisation de fichiers Unison, l'assistant de preuves formelles Coq ou la version Web de Facebook Messenger. Il dispose d'un écosystème de développement varié, avec notamment le framework Web et mobile Ocsigen et l'unikernel MirageOS. Les facilités de traitement symbolique du langage permettent le développement d'outils de vérification statique, comme le projet SLAM pour des pilotes Windows écrits par Microsoft, ou ASTRÉE pour certains systèmes embarqués des Airbus A380.

Principes

Caml est un langage fonctionnel augmenté de fonctionnalités permettant la programmation impérative. OCaml étend les possibilités du langage en permettant la programmation orientée objet et la programmation modulaire. Pour toutes ces raisons, OCaml entre dans la catégorie des langages multi-paradigme.

Il intègre ces différents concepts dans un système de types hérité de ML, caractérisé par un typage statique, fort et inféré.

Le système de types permet une manipulation aisée de structures de données complexes : on peut aisément représenter des types algébriques, c'est-à-dire des types hiérarchisés et potentiellement récursifs (listes, arbres…), et les manipuler aisément à l'aide du filtrage par motif. Cela fait de OCaml un langage de choix dans les domaines demandant la manipulation de structures de données complexes, par exemple les compilateurs.

Le typage fort, ainsi que l'absence de manipulation explicite de la mémoire (présence d'un ramasse-miettes) font de OCaml un langage très sûr. Il est aussi réputé pour ses performances, grâce à la présence d'un compilateur de code natif.

Histoire

L'équipe de développement d'OCaml recevant un prix à la conférence POPL 2024

Le langage Caml est né de la rencontre du langage de programmation ML, auquel s'est intéressée l'équipe Formel de l'Inria depuis le début des années 1980, et de la machine abstraite catégorique CAM de Guy Cousineau, fondée sur les travaux de Pierre-Louis Curien en 1984. La première implémentation, écrite par Ascander Suarez (à l'époque doctorant à l'université Paris Diderot) puis maintenue par Pierre Weis et Michel Mauny, a été publiée en 1987. Le langage s'est peu à peu différencié de son père ML car l'équipe de l'Inria voulait adapter un langage à ses propres besoins, et continuer à le faire évoluer, ce qui entrait en conflit avec la « stabilité » de ML imposée par les efforts de standardisation de Standard ML.

Les limitations de la CAM ont conduit à la création d'une nouvelle implémentation, mise au point par Xavier Leroy dès 1990, sous le nom de Caml Light. Cette implémentation — dont une version a été utilisée dans l'enseignement supérieur français jusqu’en 2017, bien après la fin de sa maintenance par l'Inria — fonctionne grâce à un interpréteur de code octet (bytecode) codé en C, ce qui lui assure une grande portabilité. Le système de gestion de la mémoire, conçu par Damien Doligez, a aussi fait son apparition dans Caml Light. En 1995, Xavier Leroy publie une version de Caml nommée Caml Special Light, qui introduit un compilateur de code natif, et un système de modules inspiré des modules de Standard ML.

OCaml, publié pour la première fois en 1996, apporte à Caml un système objet conçu par Didier Rémy et Jérôme Vouillon. Certaines fonctionnalités avancées, comme les variantes polymorphes ou les labels (permettant de distinguer les arguments donnés à une fonction par leur nom, plutôt que leur position) ont été introduites en 2000 par Jacques Garrigue. OCaml s'est relativement stabilisé depuis (malgré l'absence d'une spécification, le document en vigueur étant le manuel officiel maintenu par l'Inria). De nombreux dialectes de OCaml sont apparus, et continuent d'explorer des aspects spécifiques des langages de programmation (concurrence, parallélisme, évaluation paresseuse, intégration du XML…) ; voir la section Langages dérivés.

Principales caractéristiques

Langage fonctionnel

OCaml possède la plupart des caractéristiques communes des langages fonctionnels, en particulier des fonctions d'ordre supérieur et fermetures (closures), et un bon support de la récursion terminale.

Typage

Le typage statique d'OCaml détecte au moment de la compilation un grand nombre d'erreurs de programmation qui pourraient poser des problèmes au moment de l'exécution. Toutefois, contrairement à la plupart des autres langages, il n'est pas nécessaire de préciser le type des variables que l'on utilise. En effet, Caml dispose d'un algorithme d'inférence de types qui lui permet de déterminer le type des variables à partir du contexte dans lequel elles sont employées.

Le système de typage ML supporte le polymorphisme paramétrique, c'est-à-dire des types dont des parties seront indéterminées au moment de la définition de la valeur. Cette fonctionnalité, automatique, permet d'obtenir une généricité comparable à celle des generics de Java ou C# ou des templates de C++.

Cependant, les extensions du typage ML requises par l'intégration de fonctionnalités avancées, comme la programmation orientée objet, complexifient dans certains cas le système de types : l'utilisation de ces fonctionnalités peut alors demander un temps d'apprentissage au programmeur, qui n'est pas forcément familier des systèmes de types sophistiqués.

Filtrage

Le filtrage par motif (en anglais : pattern matching) est un élément essentiel du langage Caml. Il permet d'alléger le code grâce à une écriture plus souple que des conditions classiques, et l'exhaustivité fait l'objet d'une vérification : le compilateur propose un contre-exemple lorsqu'un filtrage incomplet est décelé. Par exemple, le code suivant est compilé mais il provoque un avertissement :

# type etat = Actif | Inactif | Inconnu;;
type etat = Actif | Inactif | Inconnu

# let est_actif = function
#   | Actif -> true
#   | Inactif -> false;;
val est_actif : etat -> bool = <fun>
Warning P: this pattern-matching is not exhaustive. Here is an example of a 
value that is not matched: Inconnu

Ainsi, le programme fonctionne lorsque la fonction est_actif est appelée avec un état valant Actif ou Inactif, mais s'il vaut Inconnu, la fonction renvoie l'exception Match_failure.

Modules

Les modules permettent de décomposer le programme en une hiérarchie de structures contenant des types et des valeurs logiquement reliés (par exemple, toutes les fonctions de manipulation de listes vont dans le module List). Les descendants de la famille ML sont les langages ayant actuellement les systèmes de modules les plus perfectionnés, qui permettent, en plus de disposer d'espaces de noms, de mettre en œuvre l'abstraction (valeurs accessibles dont l'implémentation est cachée) et la composabilité (valeurs qui peuvent être construites par-dessus différents modules, du moment qu'ils répondent à une interface donnée).

Ainsi, les trois unités syntaxiques de construction syntaxique sont les structures, les interfaces et les modules.

Les structures contiennent l'implémentation des modules.

Les interfaces décrivent les valeurs qui en sont accessibles. Les valeurs dont l'implémentation n'est pas exposée sont des valeurs abstraites. Les valeurs qui n'apparaissent pas du tout dans l'implémentation du module sont inaccessibles, à l'instar des méthodes privées en programmation orientée objet).

Un module peut avoir plusieurs interfaces (du moment qu'elles sont toutes compatibles avec les types de l'implémentation), et plusieurs modules peuvent vérifier une même interface.

Les foncteurs sont des structures paramétrées par d'autres structures ; par exemple, les tables de hachage (module Hashtbl) de la bibliothèque standard OCaml sont utilisables comme un foncteur, qui prend en paramètre toute structure implémentant l'interface composée d'un type, d'une fonction d'égalité entre les clés, et d'une fonction de hachage.

Orienté objet

OCaml se distingue particulièrement par son extension du typage ML vers un système objet comparable à ceux utilisés par les langages objets classiques. Cela permet un sous-typage structurel, dans lequel les objets sont de types compatibles si les types de leurs méthodes sont compatibles, indépendamment de leurs arbres d'héritage respectifs. Cette fonctionnalité, que l'on peut considérer comme l'équivalent du duck typing des langages dynamiques, permet une intégration naturelle des concepts objets dans un langage globalement fonctionnel.

Ainsi, à la différence des langages orientés objet tels C++ ou Java pour lesquels toute classe définit un type, les classes OCaml définissent plutôt des abréviations de types. En effet, pour peu que le type des méthodes soit compatible, deux objets de deux classes différentes peuvent être utilisés indifféremment dans un même contexte. Cette caractéristique de la couche objet de OCaml rompt bon nombre de principes communément admis : il est en effet possible de faire du sous-typage sans héritage, par exemple. Le côté polymorphe rompt le principe inverse. Des exemples de code, bien que rares, exhibant des cas d'héritage sans sous-typage existent également. La force de la couche objet tient à son homogénéité et sa parfaite intégration dans la philosophie et l'esprit même du langage OCaml. Des objets fonctionnels, dont les attributs ne peuvent être modifiés et dont les méthodes, le cas échéant, en retournent une copie avec la mise à jour des attributs, ou encore la définition d'objets immédiats, ou à la volée, sont également possibles.

Distribution

La distribution OCaml contient :

• un interpréteur interactif (ocaml) ;
• un compilateur bytecode (ocamlc) et l'interpréteur de bytecode (ocamlrun) ;
• un compilateur natif (ocamlopt) ;
• des générateurs d'analyseurs lexicaux (ocamllex) et syntaxiques (ocamlyacc) ;
• un préprocesseur (camlp4), qui permet des extensions ou modifications de la syntaxe du langage ;
• un débogueur pas à pas, avec retour en arrière (ocamldebug) ;
• des outils de profiling ;
• un générateur de documentation (ocamldoc) ;
• un gestionnaire de compilation automatique (ocamlbuild), depuis OCaml 3.10 ;
• une bibliothèque standard variée.

Les outils OCaml sont régulièrement utilisés sous Windows, GNU/Linux ou MacOS, mais existent aussi sur d'autres systèmes comme les BSD.

Le compilateur bytecode permet de créer des fichiers qui sont ensuite interprétés par ocamlrun. Le bytecode étant indépendant de la plate-forme, cela assure une grande portabilité (ocamlrun pouvant a priori être compilé sur toute plate-forme supportant un compilateur C fonctionnel). Le compilateur natif produit un code assembleur spécifique à la plate-forme, ce qui sacrifie la portabilité de l'exécutable produit pour des performances grandement améliorées. Un compilateur natif est présent pour les plates-formes IA-32, PowerPC, AMD64, Alpha, Sparc, Mips, IA-64, HPPA et StrongARM.

Une interface de compatibilité permet de lier du code OCaml à des primitives en C, et le format des tableaux de nombres flottants est compatible avec C et Fortran. OCaml permet aussi l'intégration de code OCaml dans un programme en C, ce qui permet de distribuer des bibliothèques OCaml à des programmeurs en C sans qu'ils aient besoin de connaître ou même d'installer OCaml.

Les outils OCaml sont majoritairement codés en OCaml, à l'exception de quelques bibliothèques et de l'interpréteur bytecode, qui sont codés en C. En particulier, le compilateur natif est entièrement codé en OCaml.

Gestion de la mémoire

OCaml dispose, comme Java, d'une gestion automatisée de la mémoire, grâce à un ramasse-miettes incrémental générationnel. Celui-ci est spécialement adapté à un langage fonctionnel (optimisé pour un rythme rapide d'allocation/libération de petits objets) et n'a donc pas d'impact sensible sur les performances des programmes. Il est configurable pour rester efficace dans des situations atypiques d'utilisation de la mémoire.

Performances

OCaml se distingue de la plupart des langages développés dans des milieux académiques par d'excellentes performances^{[source insuffisante]}. En plus des optimisations locales « classiques » effectuées par le générateur de code natif, les performances profitent avantageusement de la nature fonctionnelle et statiquement et fortement typée du langage.

Ainsi, les informations de typage sont complètement déterminées à la compilation, et n'ont pas besoin d'être reproduites dans le code natif, ce qui permet entre autres de retirer complètement les tests de typage au moment de l'exécution. D'autre part, certains algorithmes de la bibliothèque standard exploitent les propriétés intéressantes des structures de données fonctionnelles pures : ainsi, l'algorithme d'union d'ensembles est asymptotiquement plus rapide que celui des langages impératifs, car il utilise leur non-mutabilité pour réutiliser une partie des ensembles de départ pour constituer l'ensemble de sortie (c'est la technique de path copying pour les structures de données persistantes).

Historiquement, les langages fonctionnels ont été considérés comme lents par certains programmeurs, car ils nécessitent naturellement la mise en œuvre de concepts (récupération de la mémoire, application partielle…) qu'on ne savait pas compiler efficacement ; les progrès des techniques de compilation ont depuis permis de rattraper l'avantage initial des langages impératifs. OCaml, en optimisant efficacement ces parties du langage et en implémentant un ramasse-miettes adapté aux allocations fréquentes des langages fonctionnels, a été un des premiers langages fonctionnels à démontrer l'efficacité retrouvée de la programmation fonctionnelle.

En général, la rapidité d'exécution est légèrement inférieure à celle d'un code équivalent en C. Xavier Leroy parle prudemment de « performances d'au moins 50 % de celles d'un compilateur C raisonnable ». Ces prévisions ont depuis été confirmées par de nombreux benchmarks. En pratique, les programmes restent en général dans cette fourchette (de 1 à 2 fois celle du code C), avec des extrêmes dans les deux directions (parfois plus rapide que le C, parfois fortement ralenti par une interaction malheureuse avec le ramasse-miettes. Dans tous les cas, cela reste plus rapide que la plupart des langages récents qui ne sont pas compilés nativement, comme Python ou Ruby, et comparable aux langages statiques compilés à la volée comme Java ou C#.

Utilisation

Le langage OCaml, issu des milieux de recherche, ne bénéficie pas de la puissance publicitaire de certains langages de programmation actuels. Il reste donc relativement peu connu du grand public informatique (ainsi que la plupart des langages fonctionnels) mais est cependant solidement implanté dans quelques niches dans lesquelles les qualités du langage priment sur son absence de popularité.^{[réf. nécessaire]}

Enseignement

OCaml est le langage utilisé par certaines classes préparatoires françaises, et imposé en option informatique, où il a succédé à Caml Light, dans l'optique des épreuves d'option informatique des concours d'entrée aux grandes écoles, ainsi que le concours externe de l'agrégation section informatique.

Les documents utilisés dans le cadre de cet enseignement mettent en avant les liens entre programmation fonctionnelle et mathématiques, et l'aisance avec laquelle les langages de la famille ML manipulent les structures de données récursives, utiles pour enseigner l'algorithmique.

Il souffre dans le milieu universitaire de la concurrence du langage Haskell, qui lui est préféré dans certains cours de programmation fonctionnelle, parce qu'entre autres choses, il ne reprend aucun concept de la programmation impérative.

Recherche

OCaml est un langage assez utilisé dans le milieu de la recherche. Historiquement, les langages de la branche ML ont toujours été étroitement liés au domaine des systèmes de preuves formelles (le ML initial de Robin Milner est ainsi apparu pour être utilisé dans le système de preuves LCF). OCaml est le langage utilisé par un des logiciels majeurs du domaine, l'assistant de preuves Coq.

OCaml est présent dans de nombreux autres domaines de la recherche informatique, dont la recherche en langages de programmation et compilateurs (voir la section Langages dérivés), ou le logiciel de synchronisation de fichier Unison.

Industrie

Malgré sa communication relativement timide, OCaml a acquis une solide base d'utilisateurs dans des domaines spécifiques de l'industrie. Ainsi, l'industrie aéronautique utilise OCaml pour sa sûreté de programmation et son efficacité pour la formulation d'algorithmes complexes. On peut citer dans ce domaine le projet ASTRÉE, utilisé entre autres par l'entreprise Airbus. Le compilateur du langage de programmation temps-réel synchrone Lustre, utilisé pour les systèmes critiques tels les systèmes d'avionique des Airbus ou de contrôle de certaines centrales nucléaires, est également écrit en OCaml.

OCaml est utilisé pour le développement d'applications Web et mobiles, notamment le réseau social Be Sport.

OCaml est utilisé par des acteurs importants de l'industrie du logiciel, comme Microsoft ou XenSource, tous deux membres du Consortium Caml. Il trouve aussi des applications dans l'informatique financière, comme l'a montré l'entreprise Jane Street, qui emploie de nombreux programmeurs OCaml, ou encore LexiFi, entreprise française, spécialisée dans la conception de langages de programmation dédiés à la finance.

Enfin, il est aussi utilisé par des projets libres généralistes, comme MLDonkey, GeneWeb, le client pour webradios Liquidsoap, la bibliothèque FFTW, ainsi que certains logiciels de l'environnement de bureau KDE. Enfin, les formules mathématiques du logiciel MediaWiki sont générées par un programme écrit en OCaml.

Présentation du langage

Hello world

Soit le programme hello.ml suivant :

print_endline "Hello world!"

Il peut être compilé en bytecode exécutable avec le compilateur bytecode ocamlc :

$ ocamlc -o hello hello.ml

Il peut être également compilé en code natif optimisé exécutable avec le compilateur natif ocamlopt :

$ ocamlopt -o hello hello.ml

Le programme peut ensuite être exécuté par l'interpréteur de bytecode ocamlrun :

$ ./hello
Hello world!

ou

$ ocamlrun hello
Hello world!

Variables

L'interpréteur interactif ocaml peut être utilisé. Il lance une invite de commandes « # » à la suite duquel les instructions OCaml peuvent être saisies, terminées par les caractères ;; (ces caractères de fin d'instruction ne doivent être utilisés que dans l'interpréteur interactif, ils ne font pas partie de la syntaxe du langage). Par exemple, pour définir une variable x contenant le résultat du calcul 1 + 2 * 3, on écrit :

$ ocaml

# let x = 1 + 2 * 3;;

Après avoir saisi et validé cette expression, OCaml détermine le type de l'expression (en l'occurrence, il s'agit d'un entier) et affiche le résultat du calcul :

val x : int = 7

On peut être tenté d'effectuer toutes sortes de calculs. Cependant, il faut prendre garde à ne pas mélanger les entiers et les réels, ce que l'on fait couramment dans de nombreux langages, car en OCaml ils ne sont pas automatiquement convertis (il faut utiliser une fonction qui va prendre un entier et retourner un réel, ou l'inverse si l'opérateur utilise des entiers). Dans l'exemple qui suit, l'opérateur + s'attend à additionner deux entiers, alors qu'il s'agit de deux réels :

# 2.3 + 1.;;
Error: This expression has type float but an expression was expected of type int

Cet exemple simple permet de se faire une première idée du fonctionnement de l'algorithme d'inférence de types. En effet, lorsque nous avons écrit 2.3 + 1., nous avons ajouté les réels 2.3 et 1. avec l'opérateur + des entiers, ce qui pose un problème. En fait, pour effectuer ce calcul, nous devons nous assurer que tous les nombres ont le même type d'une part (par exemple il est impossible d'ajouter 2.3 et 1 car 1 est un entier contrairement à 1. ou 2.3), et d'autre part employer la loi de composition interne + appliquée aux réels, notée +. en OCaml. Nous aurions donc dû écrire :

# 2.3 +. 1.;;
- : float = 3.3

Fonctions

Les programmes sont souvent structurés en procédures et en fonctions.

Les procédures sont composées d'un ensemble de commandes utilisées plusieurs fois dans le programme, et regroupées par commodité sous un même nom. Une procédure ne renvoie pas de valeur, ce rôle étant dévolu aux fonctions.

De nombreux langages disposent de mots-clefs distincts pour introduire une nouvelle procédure ou une nouvelle fonction (procedure et function en Pascal, sub et function en Visual Basic…). OCaml, quant à lui, ne possède que des fonctions, et celles-ci se définissent de la même manière que les variables.

Par exemple, pour définir l'identité, on peut écrire :

# let id x = x;;

Après saisie et validation de l'expression, l'algorithme de synthèse de types détermine le type de la fonction. Cependant, dans l'exemple que nous avons donné, rien ne présage du type de x, aussi la fonction apparaît-elle comme polymorphe (à tout élément de l'ensemble 'a, elle associe une image id x qui est élément de l'ensemble 'a) :

val id : 'a -> 'a = <fun>

Pour appeler une fonction on utilise la syntaxe suivante :

# id 5;;
- : int = 5

OCaml permet également d'utiliser des fonctions anonymes, c'est-à-dire des fonctions non liées à un identifiant, grâce au mot-clé function ou fun :

# function x -> x;;
- : 'a -> 'a = <fun>

Les fonctions anonymes peuvent être appelées immédiatement ou utilisées pour définir une fonction :

# (function x -> x + 1) 4;;
- : int = 5

# let id = function x -> x;;
val id : 'a -> 'a = <fun>

Filtrage par motif

Une fonctionnalité puissante de OCaml est le filtrage par motif (pattern matching en anglais). Il peut-être défini avec les mots-clé match with ou avec une fonction anonyme, suivis pour chaque motif d'une barre verticale |, du motif, d'une flèche -> et de la valeur renvoyée :

# let est_nul x =
#   match x with
#   | 0 -> true (* la première barre verticale est facultative *)
#   | _ -> false;;
val est_nul : int -> bool = <fun>

# function
# | 0 -> true (* la première barre verticale est facultative *)
# | _ -> false;;
- : int -> bool = <fun>

Le tiret bas _ représente le motif par défaut. Il est possible de donner la même valeur à plusieurs motifs en une seule fois :

# let contient_zero (x, y) =
#   match x, y with
#   | (0, _) | (_, 0) -> true
#   | _               -> false;;
val contient_zero : int * int -> bool = <fun>

Le mot-clé when permet d'exprimer une condition sur le motif :

# let contient_zero (x, y) =
#   match x, y with
#   | (x, y) when (x = 0 || y = 0) -> true
#   | _                            -> false;;
val contient_zero : int * int -> bool = <fun>

Les caractères .. permettent d'exprimer un motif filtrant les plages de caractères :

# let est_capitale c =
#   match c with
#   | 'a'..'z' -> false
#   | 'A'..'Z' -> true
#   | _        -> failwith "lettre invalide";;
val est_capitale : char -> bool = <fun>

Le mot-clé as permet de nommer la valeur filtrée :

# let mettre_en_capitale c =
#   match c with
#   | 'a'..'z' as lettre -> Char.uppercase_ascii lettre
#   | 'A'..'Z' as lettre -> lettre
#   | _                  -> failwith "lettre invalide";;
val mettre_en_capitale : char -> char = <fun>

Récursivité

La récursivité consiste à rédiger une fonction qui fait référence à elle-même, sur le modèle de la récurrence mathématique. En OCaml, les fonctions récursives sont introduites à l'aide du mot-clef rec.

Par exemple, on peut définir la fonction factorielle :

# let rec fact n =
#   match n with
#   | 0 -> 1
#   | _ -> n * fact (n - 1);;
val fact : int -> int = <fun>

On peut définir la suite de Fibonacci par :

# let rec fib n =
#   match n with
#   | 0 -> 0
#   | 1 -> 1
#   | _ -> fib (n - 1) + fib (n - 2);;
val fib : int -> int = <fun>

Définition interne

Il est possible de définir des variables et des fonctions à l'intérieur d'une fonction à l'aide du mot-clé in.

Par exemple, on peut définir la fonction factorielle :

# let fact n =
#   let rec fact_aux m a =
#     match m with
#     | 0 -> a
#     | _ -> fact_aux (m - 1) (m * a)
#   in fact_aux n 1;;
val fact : int -> int = <fun>

On peut définir la suite de Fibonacci par :

# let fib n =
#   let rec fib_aux m a b =
#     match m with
#     | 0 -> a
#     | _ -> fib_aux (m - 1) b (a + b)
#   in fib_aux n 0 1;;
val fib : int -> int = <fun>

Récursivité terminale

Le compilateur OCaml optimise les appels terminaux : quand, pendant l'évaluation d'une fonction, la dernière étape à effectuer est l'appel d'une (autre) fonction, OCaml saute directement à cette nouvelle fonction sans conserver en mémoire l'appel de la première, devenu inutile.

En particulier, OCaml optimise la récursion terminale. Par exemple, la deuxième fonction fact ci-dessus (avec un paramètre auxiliaire a) est une fonction terminale, équivalente à une boucle, et produira un résultat équivalent, égalant ainsi les performances du code impératif correspondant.

La récursion terminale est aussi performante que l'itération ; elle est donc à préférer quand elle permet d'écrire des programmes plus clairs ou plus faciles à manipuler.

Manipulation de listes

Les listes sont très utilisées en programmation, en particulier pour les traitements récursifs. Les éléments d'une liste possèdent tous le même type. Pour construire une liste, deux écritures sont possibles, l'une avec l'opérateur de chaînage :: et l'autre avec l'opérateur ; :

# 1 :: 2 :: 3 :: [];;
- : int list = [1; 2; 3]

# [1; 2; 3];;
- : int list = [1; 2; 3]

L'opérande de droite du dernier opérateur de chaînage :: d'une expression doit être une liste :

# 1 :: 2 :: 3 :: [4; 5];;
- : int list = [1; 2; 3; 4; 5]

Il est possible de concaténer des listes avec l'opérateur de concaténation @ :

# [1; 2; 3] @ [4; 5];;
- : int list = [1; 2; 3; 4; 5]

Pour connaître la longueur d'une liste sans utiliser la fonction List.length définie à cet effet, on peut écrire :

# let rec longueur l =
#   match l with
#   | []     -> 0
#   | _ :: q -> 1 + longueur q;;
val longueur : 'a list -> int = <fun>

Lors de l'analyse de cette fonction par l'algorithme d'inférence de type, il apparaît que la liste peut contenir n'importe quel type de données 'a.

La fonction suivante crée une liste de couples à partir de deux listes : la longueur de cette liste sera égale à la longueur de la liste passée en paramètre qui est la plus courte.

# let rec couple l1 l2 =
#   match l1, l2 with
#   | ([], _) | (_, [])    -> []
#   | (t1 :: q1, t2 :: q2) -> (t1, t2) :: couple q1 q2;;
val couple : 'a list -> 'b list -> ('a * 'b) list = <fun>

La fonction suivante récupère le premier élément d'une liste :

# let premier_element l =
#   match l with
#   | []     -> failwith "liste vide"
#   | e :: _ -> e;;
val premier_element : 'a list -> 'a = <fun>

La fonction suivante récupère le deuxième élément d'une liste :

# let deuxieme_element l =
#   match l with
#   | []          -> failwith "liste vide"
#   | [_]         -> failwith "liste à un élément"
#   | _ :: e :: _ -> e;;
val deuxieme_element : 'a list -> 'a = <fun>

La fonction suivante récupère le premier élément de la première sous liste :

# let sous_premier_element l =
#   match l with
#   | []            -> failwith "liste vide"
#   | [] :: _       -> failwith "sous liste vide"
#   | (e :: _) :: _ -> e;;
val sous_premier_element : 'a list list -> 'a = <fun>

Fonctions d'ordre supérieur

Les fonctions d'ordre supérieur sont des fonctions qui prennent une ou plusieurs fonctions en entrée et/ou renvoient une fonction (on parle alors de fonctionnelle). La plupart des langages fonctionnels possèdent des fonctions d'ordre supérieur. Concernant OCaml, on peut en trouver des exemples dans les fonctions prédéfinies des modules Array, List, etc. Par exemple, l'expression suivante :

# List.map (function i -> i * i) [0; 1; 2; 3; 4; 5];;
- : int list = [0; 1; 4; 9; 16; 25]

La fonction map prend en argument la fonction anonyme qui, à tout entier i, associe son carré, et l'applique aux éléments de la liste, construisant ainsi la liste des valeurs élevées au carré.

Autre exemple :

# let double f i = f (f i);;
val double : ('a -> 'a) -> 'a -> 'a = <fun>

La fonction double prend en paramètre une fonction f et une valeur i et applique deux fois f à i.

# let trois = double (function i -> i + 1) 1;;
val trois : int = 3

# let augmente_2 = double (function i -> i + 1);;
val augmente_2 : int -> int = <fun>

# let liste =
#   double (
#     function
#     | [] -> []
#     | e :: l -> (e + 1) :: l
#   ) [1; 2; 3];;
val liste : int list = [3; 2; 3]

Voici encore un exemple :

# let rec parcours f e l =
#   match l with
#   | [] -> e
#   | t :: q -> f t (parcours f e q);;
val parcours : ('a -> 'b -> 'b) -> 'b -> 'a list -> 'b = <fun>

# (* somme des éléments de la liste [1; 1; 2] *)
# parcours (+) 0 [1; 1; 2];;
- : int = 4

# (* fonction calculant la somme des éléments d'une liste *)
# let somme_liste = parcours (+) 0;;
val somme_liste : int list -> int = <fun>

# (* fonction calculant le produit des éléments d'une liste *)
# let produit_liste = parcours ( *. ) 1.;;
val produit_liste : float list -> float = <fun>

Enfin, un dernier exemple. Ici, on se charge de définir un nouvel opérateur noté $. Cette opérateur effectue la composée de deux fonctions.

# let ( $ ) f g = function x -> f (g x)
val ( $ ) : ('a -> 'b) -> ('c -> 'a) -> 'c -> 'b = <fun>

# let f x = x * x;;
val f : int -> int = <fun>

# let g x = x + 3;;
val g : int -> int = <fun>

# let h = f $ g;;
val h : int -> int = <fun>

# (* affiche 36 *)
# print_int (h 3);;

Arbres et types récursifs

Pour définir un arbre binaire de type quelconque, on se sert d'un type récursif. On peut ainsi avoir recours à l'écriture suivante :

# type 'a arbre =
#   | Feuille
#   | Branche of 'a arbre * 'a * 'a arbre;;
type 'a arbre = Feuille | Branche of 'a arbre * 'a * 'a arbre

Cet arbre se compose de branches qui se ramifient à souhait, et se terminent par des feuilles. Pour connaître la hauteur d'un arbre, on utilise alors :

# let rec hauteur =
#   function
#   | Feuille -> 0
#   | Branche (gauche, _, droite) -> 1 + max (hauteur gauche) (hauteur droite);;
val hauteur : 'a arbre -> int = <fun>

Recherche de racine par dichotomie

# let rec dicho f min max eps =
#   let fmin = f min and fmax = f max in
#     if fmin *. fmax > 0. then failwith "Aucune racine"
#     else if max -. min < eps then (min, max) (* retourne un intervalle *)
#     else let mil = (min +. max)/.2. in
#       if (f mil) *. fmin < 0. then dicho f min mil eps
#       else dicho f mil max eps;;
val dicho : (float -> float) -> float -> float -> float -> float * float = <fun>

(* approximation de la racine carrée de 2 *)
# dicho (function x -> x *. x -. 2.) 0. 10. 0.000000001;;
- : float * float = (1.4142135618, 1.41421356238)

Mémoïsation

Voici un exemple de fonction qui utilise la mémoïsation. Il s'agit d'une fonction qui calcule le n-ième terme de la suite de Fibonacci. Contrairement à la fonction récursive classique, celle-ci mémorise les résultats et peut les ressortir en temps constant grâce à la table de hachage.

(* Taille de la table de hachage. *)
let _HASH_TABLE_SIZE = 997

(* Retourne le n-ième terme de la suite de Fibonacci. *)
let rec fibo =
  (* Pré-définitions. Ce code est exécuté une fois lors de la définition de la
     fonction, mais ne l'est pas à chaque appel. Cependant, `h` reste dans
     l'environnement de cette fonction pour chaque appel. *)
  let h = Hashtbl.create _HASH_TABLE_SIZE in
  (* Premiers termes. *)
  Hashtbl.add h 0 0;
  Hashtbl.add h 1 1;
  function
  | n when n < 0 -> invalid_arg "fibo" (* Pas de nombre négatif. *)
  | n ->
    try
      Hashtbl.find h n (* On a déjà calculé `fibo n`, on ressort donc le
                                résultat stocké dans la table `h`. *)
    with Not_found ->          (* Si l'élément n'est pas trouvé, … *)
      let r = fibo (n - 1) + fibo (n - 2) in (* … on le calcule, … *)
      Hashtbl.add h n r;                      (* … on le stocke, … *)
      r                              (* … et on renvoie la valeur. *)

Dérivation d'un polynôme

On se propose ici d'implémenter une fonction simple permettant de dériver un polynôme de degré quelconque. Il faut d'abord spécifier le type qui représentera notre polynôme :

# type polyn =
#   | Num of float         (* constante      *)
#   | Var of string        (* variable       *)
#   | Neg of polyn         (* négation       *)
#   | Add of polyn * polyn (* addition       *)
#   | Sub of polyn * polyn (* soustraction   *)
#   | Mul of polyn * polyn (* multiplication *)
#   | Div of polyn * polyn (* division       *)
#   | Pow of polyn * int;; (* exponentiation *)
type polyn = Num of float | Var of string | Neg of polyn | Add of polyn * polyn | Sub of polyn * polyn | Mul of polyn * polyn | Div of polyn * polyn | Pow of polyn * int

Maintenant, voici la fonction qui dérive ce polynôme par rapport à la variable x spécifiée en paramètre.

# let rec deriv x = function
#   | Num _ -> Num 0.
#   | Var y when y = x -> Num 1.
#   | Var _ -> Num 0.
#   | Neg p -> Neg (deriv x p) (* -p' *)
#   | Add (p, q) -> Add (deriv x p, deriv x q) (* p' + q' *)
#   | Sub (p, q) -> Sub (deriv x p, deriv x q) (* p' - q' *)
#   | Mul (p, q) -> Add (Mul (deriv x p, q), Mul (p, deriv x q)) (* p'q + pq' *)
#   | Div (p, q) -> Div (Sub (Mul (deriv x p, q), Mul (p, deriv x q)), Pow (q, 2)) (* (p'q - pq')/q^2 *)
#   | Pow (p, 0) -> Num 0.
#   | Pow (p, 1) -> deriv x p
#   | Pow (p, n) -> Mul (Num (float_of_int n), Mul (deriv x p, Pow (p, n - 1))) (* n * p' * p^(n - 1) *)
val deriv : string -> polyn -> polyn = <fun>

Différentes cibles de compilation

L'implémentation OCaml a été adaptée par d'autres auteurs à des cibles de compilation autres que le bytecode et le code natif. On trouvera :

• OCaml-Java, une distribution pour la JVM contenant ocamlc, ocamlrun, ocamldep, ocamldoc, ocamllex, menhir, un compilateur ocamljava vers la JVM ;
• OCamIL, un prototype de backend pour l'environnement .NET. Elle contient un compilateur vers du bytecode OCaml (exécutable par ocamlrun), un compilateur vers .NET et un outil comme ocamlyacc nommé ocamilyacc.

Langages dérivés

De nombreux langages étendent OCaml pour lui ajouter des fonctionnalités.

• F# est un langage de la plateforme .NET développé par Microsoft Research, fondé sur OCaml (et en partie compatible).
• MetaOCaml ajoute un mécanisme de quotations et de génération de code au runtime, qui apporte des fonctionnalités de métaprogrammation à OCaml.
• Fresh OCaml (fondé sur AlphaCaml, un autre dérivé de OCaml) facilite la manipulation de noms symboliques.
• JoCaml ajoute à OCaml un support du Join Calculus, orienté vers les programmes concurrents ou distribués.
• OcamlP3L apporte une forme particulière de parallélisme, fondée sur les « squelettes » (skeleton programming).
• GCaml ajoute le polymorphisme ad-hoc à OCaml, permettant la surcharge des opérateurs ou un marshalling conservant les informations de typage.
• OCamlDuce permet au système de types de représenter des valeurs XML ou liées à des expressions régulières. C'est un intermédiaire entre OCaml et le langage CDuce, spécialisé dans la manipulation du XML.
• Opa est un langage de développement d'applications et services web implanté en OCaml et dont le noyau reprend les fonctionnalités du langage OCaml. Par ailleurs, le compilateur Opa utilise le backend du compilateur OCaml pour générer des serveurs natifs.
• ReasonML développé par Facebook, est un langage utilisant le compilateur OCaml, permettant la compilation du code Reason (.re) et OCaml (.ml) en code source JavaScript (.js), qui peut-être à son tour compilé en bytecode, utilisé dans le navigateur web ou via un interpréteur comme Node.js.

Voir aussi

Articles connexes

• Ocsigen

Liens externes

• Site OCaml officiel
• Site OCaml de la communauté
• Ouvrages en français