BUILD.bazel

# Copyright 2018 Google LLC
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

load(":storage_examples.bzl", "storage_examples")
load(":storage_examples_common.bzl", "storage_examples_common_hdrs", "storage_examples_common_srcs")
load(":storage_examples_unit_tests.bzl", "storage_examples_unit_tests")
load(":storage_grpc_examples.bzl", "storage_grpc_examples", "storage_grpc_unit_tests")

package(default_visibility = ["//visibility:private"])

licenses(["notice"])  # Apache 2.0

cc_library(
    name = "storage_examples_common",
    testonly = True,
    srcs = storage_examples_common_srcs,
    hdrs = storage_examples_common_hdrs,
    deps = [
        "//:common",
        "//:storage",
        "//google/cloud/storage:storage_client_testing",
        "//google/cloud/testing_util:google_cloud_cpp_testing_private",
    ],
)

[cc_test(
    name = test.replace("/", "_").replace(".cc", ""),
    srcs = [test],
    deps = [
        ":storage_examples_common",
        "//:common",
        "//:storage",
        "//google/cloud/storage:storage_client_testing",
        "//google/cloud/testing_util:google_cloud_cpp_testing_private",
        "@com_google_googletest//:gtest_main",
    ],
) for test in storage_examples_unit_tests]

[cc_test(
    name = test.replace("/", "_").replace(".cc", ""),
    timeout = "long",
    srcs = [test],
    tags = [
        "integration-test",
    ],
    deps = [
        ":storage_examples_common",
        "//:common",
        "//:storage",
        "//google/cloud/testing_util:google_cloud_cpp_testing_private",
    ],
) for test in storage_examples]

[cc_test(
    name = test.replace("/", "_").replace(".cc", ""),
    srcs = [test],
    deps = [
        ":storage_examples_common",
        "//:common",
        "//:storage",
        "//:storage_grpc",
        "//:storage_grpc_mocks",
        "//google/cloud/storage:storage_client_testing",
        "//google/cloud/testing_util:google_cloud_cpp_testing_private",
        "@com_google_googletest//:gtest_main",
    ],
) for test in storage_grpc_unit_tests]

[cc_test(
    name = test.replace("/", "_").replace(".cc", ""),
    timeout = "long",
    srcs = [test],
    tags = [
        "integration-test",
    ],
    deps = [
        ":storage_examples_common",
        "//:common",
        "//:storage",
        "//:storage_grpc",
    ],
) for test in storage_grpc_examples]

cc_test(
    name = "storage_otel_samples",
    timeout = "long",
    srcs = ["storage_otel_samples.cc"],
    tags = [
        "integration-test",
    ],
    deps = [
        ":storage_examples_common",
        "//:common",
        "//:opentelemetry",
        "//:storage",
        "//:storage_grpc",
    ],
)