User:Stefan Kühn/Dresden
Jump to navigation
Jump to search
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Wikidata-Dresden-Stadtplan
[edit]Straßenverbindungen als Graph
[edit]#defaultView:Graph;Table
#------------------------------------------------------------------------------------
# Straßenverbindungen als Graph (über die Eigenschaft "physisch verbunden mit")
#------------------------------------------------------------------------------------
SELECT distinct
?item ?itemLabel ?image ?other ?otherLabel ?image2
WHERE
{
?item wdt:P131+ wd:Q1731. # Objekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
#?instance_of wdt:P279+ wd:Q376799 . # Verkehrsinfrastuktur
VALUES ?instance_of {
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
wd:Q537127 # Straßenbrücke
wd:Q3397519 # Spannbetonbrücke
wd:Q1055465 # Balkenbrücke
} # Innerortstraße oder Platz oder Brücke
?item wdt:P31 ?instance_of.
?item wdt:P2789 ?other . # verbundenes objekt
OPTIONAL {
?item wdt:P18 ?image . # grab image1
?other wdt:P18 ?image2 . # grab image2
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]" }
}
Straßen und Gebäude als Graph
[edit]#----------------------------------------------------------------
# Straßen und Gebäude als Graph (über die Eigenschaft "Straße")
#----------------------------------------------------------------
#defaultView:Graph;Table
SELECT distinct ?item ?itemLabel ?image ?other ?otherLabel ?image2
WHERE
{
?item wdt:P131+ wd:Q1731. # Adresseobjekt liegt Verwaltungseinheit Dresden (oder Subklasse)
?other wdt:P669 ?item . # Objekt hat "Straße" = Adresseobjekt
OPTIONAL {
?item wdt:P18 ?image . # grab image1
?other wdt:P18 ?image2 . # grab image2
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]" }
}
Straßenkarte zur Wartung der Eigenschaft "physisch verbunden mit"
[edit]#defaultView:Map;Table
#------------------------------------------------------------------------------------
# Straßenkarte zur Wartung der Eigenschaft "physisch verbunden mit"
#------------------------------------------------------------------------------------
SELECT ?item ?itemLabel ?coord ?line
#########################################
WITH {
SELECT ?item ?coord #("9B0058" as ?rgb)
WHERE {
?item wdt:P131 wd:Q1731 . # Objekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
VALUES ?instance_of {
wd:Q34442 # Straße
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
wd:Q537127 # Straßenbrücke
wd:Q3397519 # Spannbetonbrücke
wd:Q1055465 # Balkenbrücke
}
?item wdt:P31 ?instance_of . # Objekt ist eine Instanz von Verkehrsobjekt (Straße, Platz,...)
?item wdt:P625 ?coord . # Objekt hat Koordinate
}
} as %points
#########################################
WITH {
# Linien generieren
SELECT ?line #("009b0d" as ?rgb)
WHERE {
INCLUDE %points . # Gefundenen Punkte von oberen Abfrage übernehmen
?item wdt:P2789 ?item2 . # Objekt1 ist physisch verbunden mit Objekt2
?item2 wdt:P625 ?coord2 . # Objekt2 hat Koordinate
# Koordinate von Objekt1 auseinander nehmen
OPTIONAL{?item p:P625 / psv:P625 / wikibase:geoLatitude ?lat1 . }
OPTIONAL{?item p:P625 / psv:P625 / wikibase:geoLongitude ?lon1 . }
# Koordinate von Objekt2 auseinander nehmen
OPTIONAL{?item2 p:P625 / psv:P625 / wikibase:geoLatitude ?lat2 . }
OPTIONAL{?item2 p:P625 / psv:P625 / wikibase:geoLongitude ?lon2 . }
# String für die Linie zusammenbauen
BIND(CONCAT('LINESTRING (', STR(?lon1), ' ', STR(?lat1), ',', STR(?lon2), ' ', STR(?lat2), ')') AS ?str) .
BIND(STRDT(?str, geo:wktLiteral) AS ?line)
}
} AS %lines
#########################################
WHERE {
# jetzt Punkte und Linien für Ausgabe auf Karte ausgeben
{ INCLUDE %points }
union
{ INCLUDE %lines }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" }
}
Abfragen
[edit]Alle Objekte in Dresden
[edit]#-------------------------------------------------------------------------------
# alle Objekte in Dresden
#-------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Map;Table
SELECT DISTINCT ?item ?itemLabel ?image ?coordinate
WHERE {
?item wdt:P131+ wd:Q1731. # Objekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P625 ?coordinate. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Objekte im Umkreis von Dresden
[edit]#defaultView:Map
SELECT ?item ?itemLabel ?coordinate WHERE {
wd:Q1731 wdt:P625 ?Center. #Lage von Dresden
SERVICE wikibase:around {
?item wdt:P625 ?coordinate.
bd:serviceParam wikibase:center ?Center.
bd:serviceParam wikibase:radius "10". # 10 Kilometer around
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
#FILTER(EXISTS { ?place (wdt:P31/wdt:P279*) wd:Q1248784. })
}
Straßen und Plätze in Dresden
[edit]#---------------------------------------------------------------------------------------
# Straßen und Plätze in Dresden
#---------------------------------------------------------------------------------------
#defaultView:Map{"layer":"?instance_ofLabel"}
SELECT ?item ?itemLabel ?itemDescription ?coordinate ?instance_ofLabel
WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731. # liegt in Verwaltungseinheit Dresden
VALUES ?instance_of {
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
}
?item wdt:P31 ?instance_of. # ist Straße oder Platz
OPTIONAL{?item wdt:P625 ?coordinate.} # Koordinate für Kartendarstellung auslesen
#BIND(IF(BOUND(?street),"FFA500","7FFF00") AS ?rgb)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Museen in Dresden
[edit]#---------------------------------------------------------------------------------------
# Alle Museen der Stadt Dresden
#---------------------------------------------------------------------------------------
#defaultView:Table;Map
SELECT distinct ?item ?itemLabel ?itemDescription ?image ?coordinate
WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731 . # Liegt in Verwaltungseinheit Dresden (oder Unterklasse)
?item (wdt:P31/wdt:P279*) wd:Q33506 . # ist ein Museum (oder Unterklasse)
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
ORDER BY ?itemLabel
Kinos in Dresden
[edit]#---------------------------------------------------------------------------------------
# Kinos in Dresden (aktuelle und ehemalige)
#---------------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Table;Map
SELECT distinct ?item ?itemLabel ?itemDescription ?image ?coordinate ?article ?eroeffnung ?schliessung
WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731 . # liegt in der Verwaltungseinheit Dresden (oder Unterklasse)
#?item (wdt:P131/wdt:P279*) wd: . # liegt in der Verwaltungseinheit Dresden (oder Unterklasse)
?item (wdt:P31/wdt:P279*) wd:Q41253 . # ist ein Kino (oder Unterklasse)
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
OPTIONAL { ?item wdt:P1619 ?eroeffnung . }
OPTIONAL { ?item wdt:P3999 ?schliessung . }
OPTIONAL {
?article schema:about ?item.
?article schema:isPartOf <https://de.wikipedia.org/>.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
ORDER BY ?itemLabel
Stadtbezirke von Dresden
[edit]#---------------------------------------------------------------------------------------
# Alle 10 Stadtbezirke von Dresden (ehemals Ortsamtsbereich)
#---------------------------------------------------------------------------------------
#defaultView:Table
SELECT ?item ?itemLabel ?itemDescription ?image ?coordinate
WHERE {
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
VALUES ?instance_of {
wd:Q2740635 # Stadtbezirk in Deutschland
wd:Q4286337 # Stadtbezirk
}
?item wdt:P31 ?instance_of # ist ein Stadtbezirk (sollten 10 Stück sein)
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
ORDER BY ?itemLabel
Stadtteile von Dresden
[edit]#---------------------------------------------------------------------------------------
# (sollten 109 sein) Stadtbezirke von Dresden
#---------------------------------------------------------------------------------------
#defaultView:Table
SELECT distinct ?item ?itemLabel ?itemDescription ?image ?coordinate
WHERE {
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
?item wdt:P31 wd:Q253019 . # Ortsteil
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
ORDER BY ?itemDescription ?itemLabel
Verschwundene Objekte in Dresden
[edit]#-------------------------------------------------------------------------------
# Objekte die abgerissen oder zerstört oder aufgelöst wurden --> Abfrage auf Basis des Auflösungsdatum (P576)
#-------------------------------------------------------------------------------
#defaultView:Table;Map;ImageGrid;
SELECT ?item ?itemLabel ?itemDescription ?ende_datum ?image ?coordinate WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731 .
?item wdt:P576 ?ende_datum.
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
#FILTER(EXISTS { ?place (wdt:P31/wdt:P279*) wd:Q1248784. })
}
order by ?ende_datum ?itemLabel
Abgegangene Bauwerke in Dresden
[edit]#-------------------------------------------------------------------------------
# Abgegangene Bauwerke in Dresden
#-------------------------------------------------------------------------------
#defaultView:Map;
SELECT ?item ?itemLabel ?itemDescription ?image ?coordinate WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731 .
?item (wdt:P31/wdt:P279*) wd:Q19860854.
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Bauwerke-Typen in Dresden (Bubble Chart)
[edit]#-------------------------------------------------------------------------------
# Bauwerke-Typen in Dresden (Bubble Chart)
#-------------------------------------------------------------------------------
#defaultView:BubbleChart; Table;
select ?bautyp ?bautypLabel (COUNT(?bautyp) AS ?anzahl)
where {
SELECT distinct ?item ?itemLabel ?bautyp ?bautypLabel
WHERE {
?item wdt:P31 ?bautyp.
?item (wdt:P131/wdt:P279*) wd:Q1731 .
?item (wdt:P31/wdt:P279*) wd:Q811979.
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
}
group by ?bautyp ?bautypLabel
order by desc(?anzahl)
#order by ?bautypLabel ?item
limit 50
Unternehmen, Vereine und Behörden in Dresden
[edit]#-------------------------------------------------------------------------------
# Unternehmen, Vereine und Behörden in Dresden
#-------------------------------------------------------------------------------
#defaultView:Table
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?Steuernummer ?rechtsformLabel ?adresse ?street ?streetLabel ?coordinate ?image
WHERE {
{
?item wdt:P131 wd:Q1731. # liegt in Dresden
?item (wdt:P31/wdt:P279*) wd:Q6881511. # ist ein Unternehmen
}
union
{
?item wdt:P159 wd:Q1731. # hat Hauptverwaltung in Dresden
}
union
{
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
?item wdt:P3608 ?Steuernummer # hat eine Steuernummer
FILTER (CONTAINS(?Steuernummer, '')).
}
union
{
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
?item wdt:P1454 ?rechtsform # hat eine Rechtsform
FILTER (CONTAINS(?rechtsform, '')).
}
OPTIONAL {?item wdt:P6375 ?adresse # hat Adresse
#FILTER (CONTAINS(?adresse, '')) # Filter für die Adresse
.}
OPTIONAL { ?item wdt:P18 ?image. } # Bild
OPTIONAL { ?item wdt:P625 ?coordinate. } # Koordinate
OPTIONAL { ?item wdt:P669 ?street. } # Straße
OPTIONAL { ?item wdt:P3608 ?Steuernummer. }
OPTIONAL { ?item wdt:P1454 ?rechtsform.} #Rechtsform
?item rdfs:label ?name
#FILTER(REGEX(STR(?name), "Gl")) # Filter für Name
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Unternehmen mit Hauptverwaltung in Dresden
[edit]#-------------------------------------------------------------------------------
# Unternehmen mit Hauptverwaltung in Dresden (Headquarter)
#-------------------------------------------------------------------------------
SELECT ?item ?itemLabel ?street ?coord ?industryLabel
WHERE
{
?item wdt:P31 wd:Q4830453.
?item wdt:P159 wd:Q1731.
?item wdt:P452 ?industry.
optional {
?item p:P159 [ pq:P625 ?coord; pq:P6375 ?street;]
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Dresdner Unternehmen der Tabakindustrie
[edit]#----------------------------------------------------------
#Dresdner Unternehmen der Tabakindustrie (Headquarter)
#----------------------------------------------------------
SELECT ?item ?itemLabel ?street ?coord ?founded ?dissolved
WHERE
{
?item wdt:P31 wd:Q4830453.
?item wdt:P159 wd:Q1731.
?item wdt:P452 wd:Q907703.
?item wdt:P571 ?inception.
optional {
?item wdt:P576 ?dissolvedYear.
}
optional {
?item p:P159 [ pq:P625 ?coord; pq:P6375 ?street;]
}
BIND(str(YEAR(?inception)) AS ?founded)
BIND(str(YEAR(?dissolvedYear)) AS ?dissolved)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Gemälde in Neue und alter Meister
[edit]#----------------------------------------------------------
# Gemälde in Neue und alter Meister
#----------------------------------------------------------
#defaultView:ImageGrid
SELECT ?item ?itemLabel ?itemDescription ?image
WHERE
{
?item wdt:P31 wd:Q3305213.
{?item wdt:P276 wd:Q4890.}
union
{?item wdt:P276 wd:Q472706 .}
OPTIONAL { ?item wdt:P18 ?image. } # Bild
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Besondere Ansichten von Dresden
[edit]#---------------------------------------------------------------------------------------
# Besondere Ansichten von Dresden
#---------------------------------------------------------------------------------------
#defaultView:Map{"layer":"?instance_ofLabel"}
SELECT distinct ?item ?itemLabel ?itemDescription ?Nachtansicht ?Panoramaansicht ?Aussicht ?Luftbild ?Innenansicht ?Grundriss ?Eingang ?coordinate
WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731. # liegt in Verwaltungseinheit Dresden
{?item wdt:P3451 ?Nachtansicht} # hat Nachtansicht
union
{?item wdt:P4291 ?Panoramaansicht} # hat Panoramaansicht
union
{?item wdt:P8517 ?Aussicht} # hat Aussicht
union
{?item wdt:P8592 ?Luftbild} # hat Luftbild
union
{?item wdt:P5775 ?Innenansicht} # hat Innenansicht
union
{?item wdt:P3311 ?Grundriss} # hat Grundriss
union
{?item wdt:P9721 ?Eingang} # Bild Eingang
OPTIONAL{?item wdt:P625 ?coordinate.} # Koordinate für Kartendarstellung auslesen
#BIND(IF(BOUND(?street),"FFA500","7FFF00") AS ?rgb)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?Nachtansicht ?Panoramaansicht ?Aussicht ?Luftbild ?Innenansicht ?Grundriss ?itemLabel
Besondere Ansichten von Dresden (mit Layer zur Auswahl)
[edit]#---------------------------------------------------------------------------------------
# Besondere Ansichten von Dresden
#---------------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Map;Table
SELECT DISTINCT ?i ?iLabel ?coord ?layer ?lb ?nb ?pa ?gd ?ib ?bs ?ba ?sd ?be ?sa ?bw ?bm
WHERE {
{ ?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P8592 ?lb. BIND("Luftbild" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P3451 ?nb. BIND("Nachtbild" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P4291 ?pa. BIND("Panoramaansicht" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P3311 ?gd. BIND("Grundrissdarstellung" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P5775 ?ib. BIND("Innenansicht" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P2910 ?bs. BIND("Symbol" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P8517 ?ba. BIND("Aussicht" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P5555 ?sd. BIND("Schematische Darstellung" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P9721 ?be. BIND("Eingang" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P2713 ?sa. BIND("Schnittansicht" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P5252 ?bw. BIND("Winteransicht" AS ?layer).
} union{?i (wdt:P131/wdt:P279*) wd:Q1731. ?i wdt:P11101 ?bm. BIND("Modell" AS ?layer).
}
OPTIONAL {?i wdt:P625 ?coord. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Objekte in Dresden nach "erster schriftlicher Erwähnung" (Timeline)
[edit]#-------------------------------------------------------------------------------
# Objekte in Dresden nach "erster schriftlicher Erwähnung" (Timeline)
#-------------------------------------------------------------------------------
#defaultView:Timeline
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?first_written ?image ?coordinate WHERE {
?item wdt:P131+ wd:Q1731 . # liegt in Dresden (oder Unterklasse)
?item wdt:P1249 ?first_written. # erste schriftliche erwähung
# MINUS { ?item wdt:P31 wd:Q19860854. } # ist keine abgegangenes Bauwerk
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?first_written
Objekte in Dresden mit Schlüsselereignissen
[edit]#-------------------------------------------------------------------------------
# Objekte in Dresden mit Schlüsselereignissen
#-------------------------------------------------------------------------------
SELECT ?item ?itemLabel #?countryLabel
?significant_eventLabel (year(?start) AS ?y1) (year(?end) AS ?y2) ?altesdresden
?propLabel ?valLabel
#(year(?destroyed) AS ?yr_d)
WHERE {
?item wdt:P131 wd:Q1731 .
?item p:P793 ?stmt .
#?stmt ps:P793 wd:Q1441983 . # Filter für bestimmte Ereignisse
OPTIONAL {?stmt ps:P793 ?significant_event.} .
OPTIONAL {?stmt pq:P580|pq:P585 ?start} .
OPTIONAL {?stmt pq:P582 ?end} .
OPTIONAL {
?stmt ?pq ?val .
?pq ^wikibase:qualifier ?prop .
FILTER(?prop NOT IN (wd:P580, wd:P582, wd:P585, wd:P793, wd:P18)) .
}
#OPTIONAL {?item wdt:P17 ?country } .
#OPTIONAL {?item wdt:P576 ?destroyed } .
#OPTIONAL {?item wdt:P11855 ?altesdresden } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
order by ?y1
#ORDER BY xsd:integer(STRAFTER(str(?item), 'Q')) ?start ?propLabel
Abfragen zu externen Datenquellen
[edit]Objekte mit Verlinkung zu altesdresden.de
[edit]#---------------------------------------------------------------------------------------
# Objekte mit Verlinkung zu altesdresden.de
#---------------------------------------------------------------------------------------
#defaultView:Map;Table;
SELECT ?item ?itemLabel ?value ?valueLabel ?image ?coordinate (URI(CONCAT("https://www.altesdresden.de/index.htm?get_object=", ?value)) as ?altesDDurl)
WHERE
{
?item wdt:P11855 ?value .
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
}
Objekte mit LfDSobjectID (Landesamt für Denkmalschutz in Sachsen)
[edit]#---------------------------------------------------------------------------------------
# Objekte mit LfDSobjectID (Landesamt für Denkmalschutz in Sachsen)
#---------------------------------------------------------------------------------------
#defaultView:Map;Table
SELECT ?item ?itemLabel ?itemDescription ?image ?coordinate WHERE {
wd:Q1731 wdt:P625 ?Center. # Zentrum der Umkreissuche ist Dresden
SERVICE wikibase:around {
?item wdt:P625 ?coordinate. # Objekt muss Koordinate haben
bd:serviceParam wikibase:center ?Center.
bd:serviceParam wikibase:radius "15". # Radius von 15 Kilometer
}
?item wdt:P1708 ?LfDSid # Objekt muss LfDSid besitzen
OPTIONAL { ?item wdt:P18 ?image. } # optional Bild
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
}
Objekte mit Verlinkung zu StadtwikiDD
[edit]#---------------------------------------------------------------------------------------
# Objekte mit Verlinkung zu StadtwikiDD
#---------------------------------------------------------------------------------------
#defaultView:Map;Table;
SELECT ?item ?itemLabel ?value ?image ?coordinate (URI(CONCAT("https://www.stadtwikidd.de/wiki/", ?value)) as ?url)
WHERE
{
?item wdt:P8713 ?value
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
}
Objekte mit Verlinkung zu Openstreetmap
[edit]#---------------------------------------------------------------------------------------
# Objekte mit Verlinkung zu Openstreetmap
#---------------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Map;Table
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?way ?relation ?knoten ?coordinate ?layer
WHERE {
{
?item (wdt:P131/wdt:P279*) wd:Q1731. # in Dresden
?item wdt:P10689 ?way. # way
BIND("way" AS ?layer ) .
}
union
{
?item (wdt:P131/wdt:P279*) wd:Q1731. # in Dresden
?item wdt:P402 ?relation. # relation
BIND("relation" AS ?layer ) .
}
union
{
?item (wdt:P131/wdt:P279*) wd:Q1731. # in Dresden
?item wdt:P11693 ?knoten. # knoten
BIND("Knoten" AS ?layer ) .
}
OPTIONAL { ?item wdt:P625 ?coordinate. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Personen in Dresden
[edit]Einwohnerzahl von Dresden
[edit]#---------------------------------------------------------------------------------------
# Einwohnerzahl von Dresden
#---------------------------------------------------------------------------------------
# Einwohnerzahl von Dresden
#defaultView:AreaChart;table;
SELECT ?date (SAMPLE(?population) AS ?pop)
WHERE
{
BIND(wd:Q1731 AS ?item) . # Dresden
?item p:P1082 ?populationStatement . # Statement für Eigenschaft Einwohnerzahl (p:P...)
?populationStatement ps:P1082 ?population . # Property Statement Value
?populationStatement pq:P585 ?date . # property qualifier
FILTER (YEAR(?date) >= 1850) # Begin Zeitachse
FILTER (YEAR(?date) <= 2100) # Ende Zeitachse
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
group by ?date # Gruppieren, weil 1945 drei Werte drin stehen
#order by (?date)
Personen geboren in Dresden plus Zeitraum
[edit]#----------------------------------------------------------
# Personen geboren in Dresden plus Zeitraum
#----------------------------------------------------------
#defaultView:ImageGrid;Table
SELECT ?item ?itemLabel ?itemDescription ?image ?date_of_birth WHERE {
?item wdt:P31 wd:Q5. # Mensch
?item wdt:P19 ?place_of_birth # Geburtsort
filter (?place_of_birth = wd:Q1731) # Geburtsort ist Dresden
OPTIONAL { ?item wdt:P18 ?image. } # Bild
OPTIONAL { ?item wdt:P569 ?date_of_birth. } # Geburtstag
OPTIONAL { ?item wdt:P570 ?date_of_death. } # Todestag
FILTER (?date_of_birth >= "1974-06-01T00:00:00Z"^^xsd:dateTime) # geboren nach
FILTER (?date_of_birth <= "1975-07-01T00:00:00Z"^^xsd:dateTime) # geboren vor
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?date_of_birth
LIMIT 100
Personen, die Lehrkraft an der TU-Dresden sind/waren
[edit]#----------------------------------------------------------
# Personen, die Lehrkraft an der TU-Dresden sind/waren
#----------------------------------------------------------
SELECT ?item ?itemLabel ?firstnameLabel ?lastnameLabel ?itemDescription
WHERE
{
?item wdt:P108 wd:Q158158;
wdt:P106 wd:Q1622272;
#wdt:P106 wd:Q593644;
wdt:P569 ?born.
FILTER (?born >= "1945-01-01T00:00:00Z"^^xsd:dateTime) .
OPTIONAL { ?item wdt:P734 ?lastname . } # Nachname
OPTIONAL { ?item wdt:P735 ?firstname . } # Vorname
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,[AUTO_LANGUAGE]". }
}
order by ?lastnameLabel ?firstnameLabel
Personen, die an der Gret Palucca Hochschule lernten
[edit]#----------------------------------------------------------
# Personen, die an der Gret Palucca Hochschule lernten
#----------------------------------------------------------
select ?item ?itemLabel ?date_of_birth ?date_of_death ?itemDescription ?image where {
#?item wdt:P69 wd:Q2048456 .
?item wdt:P108 wd:Q2048456
OPTIONAL { ?item wdt:P569 ?date_of_birth. } # Geburtstag
OPTIONAL { ?item wdt:P570 ?date_of_death. } # Todestag
OPTIONAL { ?item wdt:P18 ?image. } # Bild
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?date_of_birth
Jüngsten Personen
[edit]#---------------------------------------------------------------------------------------
# Jüngsten Personen (geboren oder gestorben in Dresden)
#---------------------------------------------------------------------------------------
SELECT distinct ?item ?itemLabel ?itemDescription ?age ?pobLabel ?podLabel {
# ?item wdt:P1196 wd:Q8454 .
# ?item wdt:P1399 [] .
{?item wdt:P19 wd:Q1731}
union
{?item wdt:P20 wd:Q1731}
?item p:P569 [ a wikibase:BestRank ;
psv:P569 [ wikibase:timeValue ?birth;
wikibase:timePrecision ?precision_birth ] ] .
?item p:P570 [ a wikibase:BestRank ;
psv:P570 [ wikibase:timeValue ?death;
wikibase:timePrecision ?precision_death ] ] .
FILTER (?precision_birth > 8 && ?precision_death > 8)
BIND ((?death - ?birth)/365.25 AS ?age)
#FILTER (?age <= 18.5)
optional {?item wdt:P19 ?pob. }
optional {?item wdt:P20 ?pod. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en"}
} ORDER BY ?age
limit 50
Häufigste Todesursache der Menschen in Dresden
[edit]#---------------------------------------------------------------------------------------
# Häufigste Todesursache der Menschen in Dresden
#---------------------------------------------------------------------------------------
#defaultView:BubbleChart
SELECT ?todesursache ?todesursacheLabel (COUNT(?todesursache) AS ?anzahl)
{
?item wdt:P20 wd:Q1731.
?item wdt:P509 ?todesursache.
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en"}
} group by ?todesursache ?todesursacheLabel
order by desc(?anzahl)
Todesart und Todesursache der Menschen in Dresden (Tree)
[edit]#---------------------------------------------------------------------------------------
# Todesart und Todesursache der Menschen in Dresden
#---------------------------------------------------------------------------------------
#defaultView:Tree
select ?todesart ?todesartLabel ?todesursache ?todesursacheLabel ?person ?personLabel ?personDescription ?image
where {
?item wdt:P20 wd:Q1731.
?item wdt:P1196 ?todesart.
optional {
?item wdt:P20 wd:Q1731.
?item wdt:P1196 ?todesart.
?item wdt:P509 ?todesursache.
optional {
?person wdt:P20 wd:Q1731.
?person wdt:P509 ?todesursache.
OPTIONAL { ?person wdt:P18 ?image. }
}
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
Berühmte Personen (meisten Verlinkungen) mit Bezug zu Dresden
[edit]#------------------------------------------------------------
# Berühmte Personen (meisten Verlinkungen) mit Bezug zu Dresden
#------------------------------------------------------------
select ?item ?itemLabel ?itemDescription ?number ?image
with { # select all the numbers of sitelinks
select ?number (count(*) as ?total) { # we don't use ?total but without it the query times out, so we'll just ignore it
[] wikibase:sitelinks ?number .
} group by ?number
} as %numbers
where {
include %numbers .
filter (?number > 25) .
?item wikibase:sitelinks ?number .
?item wdt:P31 wd:Q5.
{?item wdt:P19 wd:Q1731} # geboren in Dresden
union
{?item wdt:P20 wd:Q1731} # gestorben in Dresden
union
{?item wdt:P937 wd:Q1731} # Wirkungsort in Dresden
OPTIONAL { ?item wdt:P18 ?image. } # Bild
service wikibase:label { bd:serviceParam wikibase:language "de,en" }
} order by desc(?number)
Tätigkeiten der Personen nach denen man was in Dresden benannt hat
[edit]#-----------------------------------------------------------------------
# Tätigkeiten der Personen nach denen man was in Dresden benannt hat
#-----------------------------------------------------------------------
#defaultView:BubbleChart
select ?taetigkeitLabel (count(?taetigkeit) as ?anzahl)
where {
?item wdt:P131 wd:Q1731. # Objekt liegt in Dresden
?item wdt:P138 ?person. # Objekt ist benannt nach Person
?person wdt:P31 wd:Q5. # Person ist Mensch
optional {?person wdt:P106 ?taetigkeit. } # Person hat Tätigkeit
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
group by ?taetigkeitLabel
Personen mit Bezug zu Dresden, die heute ein Jubiläum haben
[edit]#---------------------------------------------------------------------------------------
# Personen mit Bezug zu Dresden, die heute ein Jubiläum haben
#---------------------------------------------------------------------------------------
SELECT distinct ?item ?itemLabel ?firstnameLabel ?lastnameLabel ?itemDescription ?reason ?day ?testday ?diffyear ?image
WHERE
{
{?item wdt:P19 wd:Q1731} # Person mit Geburtsort = Dresden
union
{?item wdt:P20 wd:Q1731} # Person mit Todesort = Dresden
union
{?item wdt:P937 wd:Q1731} # Person mit Wirkungsort = Dresden
union
{?item wdt:P108 wd:Q158158} # Personen die an der TU angestellt sind/waren
BIND( now() as ?testday) # Testdatum (heute)
#BIND("2019-03-22T00:00:00Z"^^xsd:dateTime as ?testday) # Testdatum (beliebiger Tag)
{?item p:P569 [ a wikibase:BestRank ; # Geburtstag
psv:P569 [ wikibase:timeValue ?day;
wikibase:timePrecision ?precision_day ] ]
FILTER (?precision_day > 8 ) # Geburtstag vollständig (YYYY-MM-DD)
BIND( 'Geburtstag' as ?reason)
}
union
{?item p:P570 [ a wikibase:BestRank ; # Todestag
psv:P570 [ wikibase:timeValue ?day;
wikibase:timePrecision ?precision_day ] ]
FILTER (?precision_day > 8 ) # Todestag vollständig (YYYY-MM-DD)
BIND( 'Todestag' as ?reason)
}
filter (MONTH(?day) = MONTH(?testday)) # gleicher Monat
filter ( DAY(?day) = DAY(?testday)) # gleicher Tag
BIND (YEAR(?testday)-YEAR(?day) AS ?diffyear) # Jahresdifferenz errechnen
BIND (floor(?diffyear - (5 * floor(?diffyear/5))) AS ?mod) # Modula 5
filter (?mod = 0) # nur Jahre wo Rest = 0 (5,10,15,20,25,...)
OPTIONAL { ?item wdt:P734 ?lastname . } # Nachname
OPTIONAL { ?item wdt:P735 ?firstname . } # Vorname
OPTIONAL { ?item wdt:P18 ?image . } # optional Bild
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]"}
}
order by desc(?diffyear)
Wartungslisten
[edit]Objekte in Dresden ohne deutsches Label
[edit]PREFIX schema: <http://schema.org/>
#-------------------------------------------------------------------------------
# Objekte in Dresden ohne deutsches Label
#-------------------------------------------------------------------------------
#defaultView:Table
SELECT DISTINCT
?item ?label_de ?itemLabel ?itemDescription ?article ?image ?coordinates
WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731. # in Dresden
#Artikellink
OPTIONAL {
?article schema:about ?item.
?article schema:isPartOf <https://de.wikipedia.org/>.
}
# Commons-Link
OPTIONAL {?commons schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
}
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P625 ?coordinates. }
# kein deutsches Label
OPTIONAL {
?item rdfs:label ?label_de. # Label abspeichern
filter (lang(?label_de) = "de"). # Label nur auf Deutsch filtern
}
FILTER(!BOUND(?label_de)) # Filter Objekte, die kein deutsches Label haben
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,ru,es,fr,cs,pl,nl,dk" } # Label in anderen Sprachen anzeigen
}
order by ?itemLabel ?itemDescription ?article ?coordinates ?image
Objekte in Dresden ohne deutsche Beschreibung
[edit]PREFIX schema: <http://schema.org/>
#-------------------------------------------------------------------------------
# Objekte in Dresden ohne deutsche Beschreibung
#-------------------------------------------------------------------------------
#defaultView:Table
SELECT DISTINCT ?item ?itemLabel ?article ?image ?coordinates WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731. # in Dresden
#Artikellink
OPTIONAL {
?article schema:about ?item.
?article schema:isPartOf <https://de.wikipedia.org/>.
}
# Commons-Link
OPTIONAL {?commons schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
}
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P625 ?coordinates. }
filter not exists {?item schema:description ?desc . filter(lang(?desc)="de") } # Beschreibung auf Deutsch ist leer
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,ru,es,fr,cs,pl,nl,dk" } # Beschreibung in anderen Sprachen anzeigen
}
order by ?itemDescription
Objekte in Dresden ohne "ist eine ..."
[edit]#Objekte in der Stadt ohne "ist eine ..."
SELECT ?item ?itemLabel ?itemDescription
WHERE
{
?item (wdt:P131/wdt:P279*) wd:Q1731 # Objekt liegt in Dresden
MINUS { ?item wdt:P31 [] } . # enthält keine Aussage "ist eine"
MINUS { ?item wdt:P279 [] } . # enthält keine Aussage "Unterklasse von"
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" }
}
ORDER BY ?itemLabel
Objekte in Dresden ohne Bild
[edit]PREFIX schema: <http://schema.org/>
#-------------------------------------------------------------------------------
# Objekte in Dresden ohne Bild (nur Bilder auf Commons sind erlaubt)
#-------------------------------------------------------------------------------
#defaultView:Table;Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?article ?coordinates ?commons WHERE {
?item wdt:P131 wd:Q1731. # liegt in Dresden
optional { # Artikellink
?article schema:about ?item.
?article schema:isPartOf <https://de.wikipedia.org/>.
}
optional { # Commons-Link
?commons schema:about ?item.
?commons schema:isPartOf <https://commons.wikimedia.org/>.
}
optional {?item wdt:P31 ?instanceof }
Filter (?instanceof != wd:Q13406463). # ist keine Wikimedia-Liste
optional { ?item wdt:P18 ?image. }
FILTER(!BOUND(?image))
optional { ?item wdt:P625 ?coordinates. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
order by ?itemLabel
Objekte in Dresden ohne Koordinate
[edit]#---------------------------------------------------------------------------------------
# Geographische Objekte ohne Koordinate
#---------------------------------------------------------------------------------------
#defaultView:Table
select ?item ?itemLabel ?itemDescription ?destrictLabel ?coordinates
where{
?item (wdt:P131/wdt:P279*) wd:Q1731 . # in Dresden
OPTIONAL { ?item wdt:P18 ?image. } # Bild
minus { ?item wdt:P625 _:b1. } # kein Objekt, was eine Koordinate besitzt
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
}
order by ?itemDescription
Objekte mit "Dresden" im Label ohne Dresden als Attribut
[edit]#----------------------------------------------------------
# Objekte mit "Dresden" im Label ohne Dresden als Attribut
#----------------------------------------------------------
SELECT ?item ?itemLabel ?itemDescription ?commons ?image ?coordinates
WHERE {
?item wdt:P17 wd:Q183.
#?item wdt:P373 ?commons
MINUS { ?item wdt:P131 _:b1. } # liegt in Verwaltungseinheit ...
MINUS { ?item wdt:P159 _:b2. } # Hauptverwaltung
MINUS { ?item wdt:P276 _:b3. } # Ort ...
MINUS { ?item wdt:P138 wd:Q1731. } # benannt nach Dresden
MINUS { ?item wdt:P1269 wd:Q1731. } # Aspekt von Dresden
MINUS { ?item wdt:P1001 wd:Q1731. } # gehört zum Zuständigkeitsbereich von Dresden
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
#FILTER(REGEX(STR(?commons), "Dresden")) # Filter für Name
?item rdfs:label ?label_de. # Label abspeichern
filter (lang(?label_de) = "de"). # Label nur auf Deutsch filtern
FILTER(REGEX(STR(?label_de), "Dresden"))
optional {?item wdt:P31 ?instanceof }
Filter (?instanceof != wd:Q13406463). # keine Wikimedia-Liste
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P625 ?coordinates. }
}
Limit 100
Objekte mit Commons-Kategorie "Dresden" ohne "liegt in Dresden"
[edit]#----------------------------------------------------------
# Objekte mit Commons-Kategorie "Dresden" ohne "liegt in Dresden"
#----------------------------------------------------------
SELECT ?item ?itemLabel ?itemDescription ?commons ?image ?coordinates
WHERE {
?item wdt:P17 wd:Q183.
?item wdt:P373 ?commons
MINUS { ?item wdt:P131 _:b1. }
MINUS { ?item wdt:P159 _:b2. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
FILTER(REGEX(STR(?commons), "Dresden")) # Filter für Name
optional {?item wdt:P31 ?instanceof }
Filter (?instanceof != wd:Q13406463). # keine Wikimedia-Liste
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P625 ?coordinates. }
}
Objekte ohne Eigenschaft Straße, die in der Adresse den Namen eines Straßen-Objektes haben
[edit]#---------------------------------------------------------------------------------------
# Objekte ohne Eigenschaft Straße, die in der Adresse den Namen eines Straßen-Objektes haben
#---------------------------------------------------------------------------------------
#defaultView:Table
SELECT distinct ?item ?itemLabel ?adress ?itemstreetLabel ?streetname
WHERE {
?street wdt:P131+ wd:Q1731. # liegt in Verwaltungseinheit Dresden
VALUES ?instance_of {
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
}
?street wdt:P31 ?instance_of. # ist Straße oder Platz
?street rdfs:label ?streetname . # gibt den Namen von der Straße
filter(lang(?streetname)="de") . # gib aber nur den deutschen Straßennamen
?item wdt:P131+ wd:Q1731. # Objekt liegt in Verwaltungseinheit Dresden
?item wdt:P6375 ?adress. # Objekt hat Adresse
OPTIONAL {?item wdt:P669 ?itemstreet. }
FILTER(!BOUND(?itemstreet)). # Objekt hat keine Straße
FILTER (CONTAINS(?adress, ?streetname)) . # Objekt-Adresse enthält Straßenname
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?streetname
Objekte ohne Eigenschaft "Straße"
[edit]#---------------------------------------------------------------------------------------
# Objekte ohne Eigenschaft "Straße"
#---------------------------------------------------------------------------------------
#defaultView:Map{"layer":"?instance_ofLabel"}
SELECT ?item ?itemLabel ?itemDescription ?coordinate ?instance_of ?instance_ofLabel
WHERE {
{
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
?item wdt:P625 ?coordinate. # kein Objekt, was eine Koordinate besitzt
OPTIONAL{?item wdt:P669 ?street.}
FILTER(!BOUND(?street)).
}
union
{
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
VALUES ?instance_of {
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
}
?item wdt:P31 ?instance_of. # ist Straße oder Platz
?item wdt:P31 ?coordinate.
}
#BIND(IF(BOUND(?street),"FFA500","7FFF00") AS ?rgb)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Objekte ohne Eigenschaft "liegt in Verwaltungsgebiet"
[edit]#---------------------------------------------------------------------------------------
# Objekte ohne Eigenschaft "liegt in Verwaltungsgebiet"
#---------------------------------------------------------------------------------------
#defaultView:Map;Table
SELECT distinct ?item ?itemLabel ?itemDescription ?image ?coordinate
WHERE {
wd:Q1731 wdt:P625 ?Center. #Lage von Dresden
SERVICE wikibase:around {
?item wdt:P625 ?coordinate.
bd:serviceParam wikibase:center ?Center.
bd:serviceParam wikibase:radius "15". # 15 Kilometer around
}
#?item wdt:P131/wdt:P131 ?verwaltungseinheit.
minus { ?item wdt:P131 _:b1. }
OPTIONAL { ?item wdt:P159 ?hauptverwaltung. }
filter (!bound(?hauptverwaltung))
OPTIONAL { ?item wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
#FILTER(EXISTS { ?place (wdt:P31/wdt:P279*) wd:Q1248784. })
}
Verwaltungsstruktur säubern - TODO
[edit]#---------------------------------------------------------------------------------------
# Mit dieser Abfrage soll die Verwaltungsstruktur bereinigt werden - Work in Progress
#---------------------------------------------------------------------------------------
select ?item ?itemLabel ?itemDescription ?liegt_inLabel ?liegt_inDescription #?image ?coordinate
where {
?item wdt:P131 wd:Q1731 .
#?item wdt:P31 wd:Q11183787. # OK 9/9 Ortschaften
#?item wdt:P31 wd:Q2740635. # OK 10/10 Stadtbezirk in Deutschland (ab 13. September 2018) - Sollten alle mit Wort "Stadtbezirk" beginnen, damit von Stadtteil unterscheidbar!
#?item wdt:P31 wd:Q18600372 # OK 10/10 Ortsamtsbereich ( 1991 - 13. September 2018)
#?item wdt:P31 wd:Q4286337. # OK 0/0 Stadtbezirk --> Stadtbezirk in Deutschland
#?item wdt:P31 wd:Q123705 # 3x Stadtviertel oder Ortsteil
#?item wdt:P31 wd:Q253019 # 124x Ortsteil
?item wdt:P31 wd:Q2333944 # 26/64 Statistischer Stadtteil
OPTIONAL { ?item wdt:P131 ?liegt_in. }
#OPTIONAL { ?item wdt:P18 ?image. }
#OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?liegt_inLabel ?itemDescription
Objekte ohne Bild, aber mit Commons-Kategorie
[edit]#---------------------------------------------------------------------------------------
# Objekte ohne Bild, aber mit Commons-Kategorie
#---------------------------------------------------------------------------------------
SELECT ?item ?itemLabel ?itemDescription
WHERE
{
?item wdt:P131+ wd:Q1731 .
?article schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
filter not exists {?item wdt:P18 [] .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?itemDescription ?itemLabel
Objekte mit PLZ von Dresden, ohne Koordinate
[edit]#-------------------------------------------------------------------------------
# Objekte mit PLZ von Dresden, ohne Koordinate
#-------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Table
select distinct ?item ?itemLabel ?itemDescription ?plz ?image
where {
?item wdt:P281 ?plz. # Objekt hat Postleitzahl
?item2 wdt:P281 ?plz. # Vergleichsobjekt hat Postleitzahl
FILTER(REGEX(STR(?plz), "^01[0-9]+$")) # PLZ ist 01...
?item2 wdt:P131+ wd:Q1731. # Vergleichsobjekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
OPTIONAL { ?item wdt:P18 ?image. } # Objekt hat optional Bild
OPTIONAL { ?item wdt:P625 ?coordinate. }# Objekt hat optional Koordinate
FILTER(!BOUND(?coordinate)) # Objekt hat leeres Datenfeld bei Koordinate
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Limit 100
Wartungslisten für Personen
[edit]Person in Dresden geboren und ohne Bild
[edit]#-------------------------------------------------------------------------------
# Person in Dresden geboren und ohne Bild (nur Bilder von Commons sind erlaubt)
#-------------------------------------------------------------------------------
#defaultView:Table;ImageGrid
SELECT distinct ?item ?itemLabel ?itemDescription ?artikel_de ?commons ?image ?date_of_birth WHERE {
?item wdt:P31 wd:Q5. # Mensch
#?item rdfs:label ?name
#FILTER(REGEX(STR(?name), "^Ste"))
?item wdt:P19 ?place_of_birth # Geburtsort
filter (?place_of_birth = wd:Q1731) # Geburtsort ist Dresden
OPTIONAL { ?item wdt:P18 ?image. } # Bild
FILTER(!BOUND(?image))
OPTIONAL { ?item wdt:P569 ?date_of_birth. } # Geburtstag
OPTIONAL { ?item wdt:P570 ?date_of_death. } # Todestag
OPTIONAL { ?item wdt:P373 ?commonsProp.} # Commons als Prop
FILTER (?date_of_birth >= "974-06-01T00:00:00Z"^^xsd:dateTime) # geboren nach
FILTER (?date_of_birth <= "2975-07-01T00:00:00Z"^^xsd:dateTime) # geboren vor
# Commons-Link (über "Andere Websites")
OPTIONAL {?commons schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
}
OPTIONAL { ?artikel_de schema:about ?item.
FILTER(REGEX(STR(?artikel_de), "de.wikipedia.org/wiki/"))
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
order by ?date_of_birth
#LIMIT 100
Personen mit Arbeitgeber TU-Dresden ohne deutsche Beschreibung
[edit]#----------------------------------------------------------
# Personen mit Arbeitgeber TU-Dresden ohne deutsche Beschreibung
#----------------------------------------------------------
SELECT ?item ?itemLabel ?itemDescription
WHERE
{
?item wdt:P108 wd:Q158158
filter not exists {?item schema:description ?desc . filter(lang(?desc)="de") }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
}
Personen mit Bezug zu Dresden, ohne Tätigkeit
[edit]#---------------------------------------------------------------------------------------
# Personen mit Bezug zu Dresden, ohne Tätigkeit
#---------------------------------------------------------------------------------------
SELECT distinct ?item ?itemLabel ?firstnameLabel ?lastnameLabel ?itemDescription ?image
WHERE
{
{?item wdt:P19 wd:Q1731} # Person mit Geburtsort = Dresden
union
{?item wdt:P20 wd:Q1731} # Person mit Todesort = Dresden
union
{?item wdt:P937 wd:Q1731} # Person mit Wirkungsort = Dresden
union
{?item wdt:P108 wd:Q158158} # Personen die an der TU angestellt sind/waren
?item wdt:P31 wd:Q5 . # Only humans
FILTER NOT EXISTS { ?item wdt:P106 [] } . # Person ohne Tätigkeit
filter exists {?item schema:description ?desc . filter(lang(?desc)="de") } # Beschreibung auf Deutsch ist leer
OPTIONAL { ?item wdt:P734 ?lastname . } # Nachname
OPTIONAL { ?item wdt:P735 ?firstname . } # Vorname
OPTIONAL { ?item wdt:P18 ?image . } # optional Bild
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]"}
}
order by ?itemDescription
Wartungslisten für Bauwerke
[edit]Bauwerke mit Auflösungsdatum, aber ohne Eigenschaft "abgegangenes Bauwerk"
[edit]#-------------------------------------------------------------------------------
# Bauwerke mit Auflösungsdatum, aber ohne Eigenschaft "abgegangenes Bauwerk"
#-------------------------------------------------------------------------------
#defaultView:Map;
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?image ?coordinate WHERE {
?item (wdt:P131/wdt:P279*) wd:Q1731 . # liegt in Dresden (oder Unterklasse)
?item (wdt:P31/wdt:P279*) wd:Q811979. # ist ein Bauwerk (oder Unterklasse)
?item wdt:P576 ?ende_datum. # hat eine Endedatum
MINUS { ?item wdt:P31 wd:Q19860854. } # ist keine abgegangenes Bauwerk
OPTIONAL { ?item wdt:P18 ?image . }
OPTIONAL { ?item wdt:P625 ?coordinate . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}
Bauwerke mit Eigenschaft "ist ein Bauwerk", verfeinern
[edit]#-------------------------------------------------------------------------------
# ist ein Bauwerk --> todo genauer: Gebäude, Wohngebäude, Bürogebäude, Wasserturm, ...
#-------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Table;Map;ImageGrid;
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?image ?coordinate
WHERE {
?item wdt:P131+ wd:Q1731. # Objekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
?item wdt:P31 wd:Q811979.
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P625 ?coordinate. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,[AUTO_LANGUAGE]". }
}
order by ?itemLabel ?itemDescription
Wartungslisten für die Straßen in Dresden
[edit]Straßen, Plätze und Brücken in Dresden ohne "Commons-Kategorie"
[edit]#-------------------------------------------------------------------------------
# Straßen, Plätze und Brücken in Dresden ohne "Commons-Kategorie"
#-------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Table;Map{"layer": ?named_after, "hide": ["?coordinates", "?instance_ofLabel"]}
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?article ?commons ?image ?coordinates
WHERE {
?item wdt:P131 wd:Q1731. # Objekt liegt in Dresden
VALUES ?instance_of { wd:Q79007 wd:Q174782 wd:Q537127} # Liste von Objekttypen definieren: Innerortstraße oder Platz oder Brücke
?item wdt:P31 ?instance_of # nur Objekte mit passenden Objekttyp
OPTIONAL { # optional: deutschsprachigen Wikipedia-Artikel anzeigen
?article schema:about ?item.
?article schema:isPartOf <https://de.wikipedia.org/>.
}
OPTIONAL {?item wdt:P373 ?commons.}
FILTER(!BOUND(?commons)) #commons leer
?item wdt:P18 ?image. # optional: Bild
OPTIONAL { ?item wdt:P625 ?coordinates. } # optional: Koordinate (für Ansicht in Karte)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". } # Sprachausgabe deutsch
#?item rdfs:label ?streetname . # Straßennamen an Variable binden
#FILTER(REGEX(STR(?streetname), "Kon")). # Straßennamen filtern
}
order by ?itemLabel
Straßen, Plätze und Brücken ohne "benannt nach"
[edit]#-------------------------------------------------------------------------------
# Straßen, Plätze und Brücken in Dresden ohne "benannt nach"
#-------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Table;Map{"layer": ?named_after, "hide": ["?coordinates", "?instance_ofLabel"]}
SELECT DISTINCT ?item ?itemLabel ?named_after ?article ?coordinates
WHERE {
?item wdt:P131 wd:Q1731. # Objekt liegt in Dresden
VALUES ?instance_of { wd:Q79007 wd:Q174782 wd:Q537127} # Liste von Objekttypen definieren: Innerortstraße oder Platz oder Brücke
?item wdt:P31 ?instance_of # nur Objekte mit passenden Objekttyp
OPTIONAL { # optional: deutschsprachigen Wikipedia-Artikel anzeigen
?article schema:about ?item.
?article schema:isPartOf <https://de.wikipedia.org/>.
}
OPTIONAL {?item wdt:P138 ?named_after. } # optional: benannt nach anzeigen
FILTER(!BOUND(?named_after)) # Abfrage nach leerem Datenfeld
OPTIONAL { ?item wdt:P18 ?image. } # optional: Bild
OPTIONAL { ?item wdt:P625 ?coordinates. } # optional: Koordinate (für Ansicht in Karte)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". } # Sprachausgabe deutsch
#?item rdfs:label ?streetname . # Straßennamen an Variable binden
#FILTER(REGEX(STR(?streetname), "^Kon")). # Filter: Straßennamen beginnt mit "Kon..."
}
ORDER BY ?named_after ?itemLabel
Verkehrsobjekte in Dresden ohne physische Verbindung
[edit]PREFIX schema: <http://schema.org/>
#-------------------------------------------------------------------------------
# Verkehrsobjekte in Dresden ohne physische Verbindung
#-------------------------------------------------------------------------------
#defaultView:Map
SELECT ?item ?itemLabel ?coord (count (?connect) as ?anzahl) ?rgb
WHERE {
?item wdt:P131 wd:Q1731.
VALUES ?instance_of {
wd:Q34442 # Straße
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
wd:Q537127 # Straßenbrücke
wd:Q3397519 # Spannbetonbrücke
wd:Q1055465 # Balkenbrücke
}
?item wdt:P31 ?instance_of.
OPTIONAL {?item wdt:P2789 ?connect. }
Optional{ ?item wdt:P625 ?coord. }
BIND( IF( BOUND(?connect) , "6db26c", "ff2d00") AS ?rgb).
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
group by ?item ?itemLabel ?coord ?rgb
Straßen in Deutschland ohne Stadt
[edit]#-----------------------------------------------------------------------
# Straßen in Deutschland ohne Stadt
#-----------------------------------------------------------------------
#defaultView:map;Table
SELECT ?item ?itemLabel ?image ?coordinates
WHERE {
?item (wdt:P31/wdt:P279*) wd:Q79007. # Innerortsstraßen
?item wdt:P17 wd:Q183. # in Deutschland
MINUS { ?item wdt:P131 _:b1. } # ohne "liegt in Verwaltungseinheit" P131
OPTIONAL { ?item wdt:P18 ?image. } # Bild
OPTIONAL { ?item wdt:P625 ?coordinates. } # Koordinate
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
ORDER BY ?itemLabel
Adresseliste
[edit]PREFIX schema: <http://schema.org/>
#-------------------------------------------------------------------------------
# Objekte in Dresden mit Adresse ( Eigenschaft Straße einpflegen, wenn Straßenobjekt vorhanden)
#-------------------------------------------------------------------------------
#defaultView:Table
SELECT DISTINCT ?item ?itemLabel ?adresse ?street ?streetLabel ?housenumber ?postcode ?coordinate WHERE {
?item wdt:P131 wd:Q1731. # liegt in Verwaltungseinheit Dresden
?item wdt:P6375 ?adresse # hat Adresse
#MINUS { ?item wdt:P669 [ ]. } # minus Objekte, die eine Straßenangabe haben
#FILTER (CONTAINS(?adresse, 'Theaterplatz')) # für Einschränkungen Straßen name
OPTIONAL { ?item wdt:P625 ?coordinate. } # Koordinte
OPTIONAL { ?item wdt:P669 ?street. } # Straße
OPTIONAL { ?item p:P669 [ pq:P670 ?housenumber ] . } # Hausnummer
OPTIONAL { ?item p:P669 [ pq:P281 ?postcode ] . } # Postleitzahl
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
order by ?adresse
Straßen, Plätze und Brücken in Dresden ohne Bild (Umkreissuche)
[edit]#-------------------------------------------------------------------------------
# Straßen, Plätze und Brücken in Dresden ohne Bild (Umkreissuche)
#-------------------------------------------------------------------------------
#defaultView:Map
SELECT ?item ?itemLabel ?coordinate WHERE {
wd:Q21161975 wdt:P625 ?Center. #Objekt im Zentrum für den Umkreis (z.B. Altmarkt Dresden)
VALUES ?instance_of { wd:Q79007 wd:Q174782 wd:Q537127} # Liste von Objekttypen definieren: Innerortstraße oder Platz oder Brücke
?item wdt:P31 ?instance_of # nur Objekte mit passenden Objekttyp
SERVICE wikibase:around {
?item wdt:P625 ?coordinate.
bd:serviceParam wikibase:center ?Center.
bd:serviceParam wikibase:radius "0.8". # Radius für den Umkreise in Kilometer (z.B. "0.5" für 500 Meter)
}
optional { ?item wdt:P18 ?image. }
FILTER(!BOUND(?image))
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
#FILTER(EXISTS { ?place (wdt:P31/wdt:P279*) wd:Q1248784. })
}
Straßen, Plätze und Brücken in Dresden (Übersicht mit Stadtwiki und Themenstadtplan)
[edit]#-------------------------------------------------------------------------------
# Straßen, Plätze und Brücken in Dresden (Übersicht mit Stadtwiki und Themenstadtplan)
#-------------------------------------------------------------------------------
PREFIX schema: <http://schema.org/>
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?image
(URI(CONCAT("https://stadtplan.dresden.de/?POS-ADR=",?DDstreetID)) as ?DDstreetID_link)
(URI(CONCAT("https://www.stadtwikidd.de/wiki/",?stadtwikiDD)) as ?stadtwikiDD_link)
?commons2 ?coordinate ?status ?rgb
WHERE {
?item wdt:P8710 ?streetID
OPTIONAL { ?item wdt:P373 ?commons. } # Commons-Kategorie
#FILTER(!BOUND(?commons)) #commons leer
OPTIONAL { ?item wdt:P18 ?image. } # optional: Bild
OPTIONAL { ?item wdt:P625 ?coordinate. } # optional: Koordinate (für Ansicht in Karte)
SERVICE wikibase:label { bd:serviceParam wikibase:language "de". } # Sprachausgabe deutsch
BIND(BOUND(?commons) && strlen(?commons)>0 as ?check_cat) # true/false - gibt es eine Commons-Category
BIND(BOUND(?image) as ?check_img) # true/false - gibt es ein Bild
BIND( IF( ?check_img , "image",
IF( ?check_cat , "category",
"no cat")) AS ?status).
BIND( IF( ?check_img , "7FFF00",
IF( ?check_cat , "009500",
"ff2d00")) AS ?rgb).
# https://htmlcolorcodes.com/
# 7FFF00 neongrün
# 009500 dunkelgrün
# FFF000 gelb
# 9B0058 rot
# ff2d00 hellrot
OPTIONAL {?item wdt:P8713 ?stadtwikiDD . }
OPTIONAL {?item wdt:P8710 ?DDstreetID . }
OPTIONAL {?commons2 schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
}
#?item rdfs:label ?streetname . # Straßennamen an Variable binden
#FILTER(REGEX(STR(?streetname), "Kon")). # Straßennamen filtern
}
Verkehrsobjekte in Dresden ohne physische Verbindung zu zweiter Straße
[edit]PREFIX schema: <http://schema.org/>
#-------------------------------------------------------------------------------
# Verkehrsobjekte in Dresden ohne physische Verbindung zu zweiter Straße
#-------------------------------------------------------------------------------
#defaultView:Map
SELECT distinct ?itemA ?itemALabel ?itemB ?itemBLabel ?coordinate
WHERE {
?itemA wdt:P131 wd:Q1731.
VALUES ?instance_of {
wd:Q34442 # Straße
wd:Q79007 # Innerortstraße
wd:Q21000333 # Einkaufsstraße
wd:Q174782 # Platz
wd:Q537127 # Straßenbrücke
wd:Q3397519 # Spannbetonbrücke
wd:Q1055465 # Balkenbrücke
}
?itemA wdt:P31 ?instance_of. # Straße A ist Verkehrsobjekt
?itemA wdt:P2789 ?itemB. # Straße A ist verbunden mit Straße B
FILTER NOT EXISTS { ?itemB wdt:P2789 ?itemA } # Straße B ist nicht verbunden mit Straße A
OPTIONAL{ ?itemB wdt:P2789 ?strassen. } # Straße B hat Eigenschaft "physisch verbunden"
FILTER(BOUND(?strassen)) # Straße B hat Eigenschaft "physisch verbunden" ist nicht leer
OPTIONAL { ?itemA wdt:P625 ?coordinate. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
order by ?itemALabel ?itemBLabel