User:MTheiler

From Wikidata
Jump to navigation Jump to search
This user has basic understanding of the Pywikibot software library.
Babel user information
de-N Dieser Benutzer spricht Deutsch als Muttersprache.
en-3 This user has advanced knowledge of English.
fr-1 Cet utilisateur dispose de connaissances de base en français.
This user has a page on Wikipedia.
This user has a page on Wikimedia Commons.
This user has a page on Wikivoyage.
Users by language

Coordinate_Me_2024

[edit]

Coordinate_Me_2024

SPARQL

[edit]

Infos zur IBA27 Region Stuttgart

[edit]

Diese SPARQL-Datenbankabfrage ermittelt Wikidata-Objekte, die als Teil der Internationale Bauausstellung 2027 StadtRegion Stuttgart gekennzeichnet sind 

SELECT ?wdItem ?wdItemLabel ?ortLabel ?erbaut ?commonskat ?koordinaten ?bild  ?zustandLabel 
WHERE {
  ?wdItem wdt:P361 wd:Q109712230 .
  OPTIONAL { ?wdItem wdt:P373   ?commonskat } .
  OPTIONAL { ?wdItem wdt:P18    ?bild } .
  OPTIONAL { ?wdItem wdt:P131   ?ort } .
  OPTIONAL { ?wdItem wdt:P625   ?koordinaten } .
  OPTIONAL { ?wdItem wdt:P571   ?erbaut } .
  OPTIONAL { ?wdItem wdt:P5817   ?zustand } 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  }
Try it!

TODO: eventuell OPTIONAL { ?wdItem wdt:P973 ?beschriebenInURL } einfügen

SPARQL - Beispiel: Nach Frauen benannte Schulen

[edit]

Diese SPARQL-Datenbankabfrage ermittelt Schulen in Deutschland, die nach Frauen benannt sind. 

SELECT ?schule ?schuleLabel ?personLabel  # Liste der ausgegebenen Variablen
WHERE 
{
  ?schule wdt:P31  wd:Q3914   .  # ist eine Schule
  ?schule wdt:P17  wd:Q183    .  # die Schule liegt im Staat Deutschland
  ?schule wdt:P138 ?person    .  # die Schule ist benannt nach ?person
  ?person wdt:P31  wd:Q5      .  # ?person ist ein Mensch
  ?person wdt:P21  wd:Q6581072.  # ?person ist weiblich
   
  # dieser SERVICE erzeugt die Ausgabe von ?schuleLabel (also dem Namen der Schule),
  # und von ?personLabel (dem Namen der Person) 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

SPARQL - Beispiel: Nach Personen benannte Schulen ohne Bild

[edit]

Diese SPARQL-Datenbankabfrage ermittelt Schulen in Deutschland, die nach Personen benannt sind und zu denen kein Bild existiert. 


SELECT ?schule ?schuleLabel ?personLabel ?stadtLabel   # Liste der ausgegebenen Variablen
WHERE 
{
  ?schule wdt:P31  wd:Q3914 .  # ist eine Schule
  ?schule wdt:P17  wd:Q183  .  # die Schule liegt im Staat Deutschland
  ?schule wdt:P131 ?stadt   .  # die Schule liegt in der Verwaltungseinheit ?stadt 
  ?schule wdt:P138 ?person  .  # die Schule ist benannt nach ?person
  ?person wdt:P31  wd:Q5    .  # ?person ist ein Mensch
  
  # Bedingung: Es existiert kein Bild dieser Schule
  FILTER NOT EXISTS { ?schule wdt:P18 ?bild } 
   
  # dieser SERVICE erzeugt die Ausgabe von ?schuleLabel (also dem Namen der Schule),
  # von ?personLabel (dem Namen der Person) und ?stadtLabel (Name der Verwaltungseinheit)        
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!


SPARQL - Beispiel: Nach Personen benannte Schulen (komplex)

[edit]

Diese SPARQL-Datenbankabfrage ermittelt Schulen in Deutschland, die nach Personen benannt sind. Zusätzlich wird der name der Stadt, in der jede dieser Schulen liegt, ermittelt. Ein eventuell vorhandenes Bild der Schule kann angezeigt werden. (Mausklick in der Karte auf den jeweiligen Punkt.) In der Darstellung auf der Karte wird nach weiblichen / nicht weiblichen Namensgebern der Schulen unterschieden. Die Punkte auf der Landkarte unterscheiden sich farblich entsprechend dem Geschlecht des Namensgebers/-geberin. 

SELECT ?item ?itemLabel ?personLabel ?stadtLabel ?bild ?coordinate  ?layer  # Liste der ausgegebenen Variablen
WHERE 
{
  ?item wdt:P31 wd:Q3914 .       # ?item ist eine Schule
  ?item wdt:P17 wd:Q183  .       # ?item liegt im Staat Deutschland
  ?item wdt:P131 ?stadt  .       # ?item liegt in der Verwaltungseinheit ?stadt 
  OPTIONAL { ?item wdt:P18  ?bild  } .   # ?item hat das Bild ?bild oder ist leer 
  ?item wdt:P625 ?coordinate  .  # ?item hat die geographischen Koordinaten 
  ?item wdt:P138 ?person      .  # ist benannt nach ?person
  ?person wdt:P31 wd:Q5       .  # ?person ist ein Mensch
  ?person wdt:P21 ?geschlecht .  # ?person hat das Geschlecht

  # Durch Abfrage der Variablen ?geschlecht werden unterschiedliche farbige Markierungen auf der Landkarte erzeugt
  # Dies geschieht mit Hilfe der Variablen ?layer 
  BIND(IF ((?geschlecht = wd:Q6581072), "Frau", "Mann" )
     AS ?layer )
  
  # dieser SERVICE erzeugt die Ausgabe von ?itemLabel (also dem namen der Schule),
  # von ?personLabel (dem Namen der Person) und ?stadtLabel (Name der Verwaltungseinheit)        
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

SPARQL - Alle Wikidata-Items im Radius von 2km um einen vorgegebenen Mittelpunkt

[edit]
# Q83467407 = Rathaus Fellbach (oder sonstiger Mittelpunkt)
SELECT ?item ?itemLabel ?location WHERE
{
  wd:Q83467407 wdt:P625 ?mittelpunktFellbach .   # Rathaus Fellbach hat die Koordinate 
  SERVICE wikibase:around { 
      ?item wdt:P625 ?location . 
      bd:serviceParam wikibase:center ?mittelpunktFellbach . 
      bd:serviceParam wikibase:radius "2" . 
  } 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de" . 
  }
}
Try it!

SPARQL - Alle Wikidata-Items im Radius von 2km um XXX ohne Bild

[edit]
# Q83467407 = Rathaus Fellbach (oder sonstiger Mittelpunkt)
SELECT ?item ?itemLabel ?location WHERE
{
  wd:Q83467407 wdt:P625 ?mittelpunktFellbach .   # Rathaus Fellbach hat die Koordinate 
  SERVICE wikibase:around { 
      ?item wdt:P625 ?location . 
      bd:serviceParam wikibase:center ?mittelpunktFellbach . 
      bd:serviceParam wikibase:radius "2" . 
  } 
  FILTER NOT EXISTS { ?item wdt:P18 ?bild } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" .  }
}
Try it!

SPARQL - Alle Wikidata-Items im Radius von 3km um XXX mit Objekt-typ

[edit]
# Q574249 = Lorch (oder sonstiger Mittelpunkt)
#defaultView:Map{"hide":["?location"]}
SELECT ?item ?itemLabel ?location ?instanceOfLabel ?bild WHERE
{
  wd:Q574249 wdt:P625 ?mittelpunktFellbach .   # Rathaus Fellbach hat die Koordinate 
  ?item wdt:P31 ?instanceOf .
  
  SERVICE wikibase:around { 
      ?item wdt:P625 ?location . 
     
      bd:serviceParam wikibase:center ?mittelpunktFellbach . 
      bd:serviceParam wikibase:radius "3" . 
  } 
  OPTIONAL { ?item wdt:P18  ?bild  } .   # ?item hat das Bild ?bild oder ist leer 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de" . 
  }
}
Try it!

SPARQL - Wikidata-Items in Stuttgart mit geographischer Koordinate aber ohne Bild

[edit]

Das Ergebnis dieser Abfrage kann als Liste oder als Map (Landkarte mit Markierungen) dargestellt werden. 

# Wikidata-Items in Stuttgart mit geographischer Koordinate aber ohne Bild
SELECT ?item ?itemLabel ?itemDescription ?coordinate # Liste der ausgegebenen Variablen
WHERE 
{
  ?item wdt:P17  wd:Q183     .  # ?item liegt im Staat Deutschland
  ?item wdt:P131 wd:Q1022    .  # ?item liegt in der Verwaltungseinheit Stuttgart 
  ?item wdt:P625 ?coordinate .  # ?item hat die geographische Koordinate ?coordinate
  
  # Bedingung: Es existiert kein Bild 
  FILTER NOT EXISTS { ?item wdt:P18 ?bild } 
   
  # dieser SERVICE erzeugt die Ausgabe von ?itemLabel 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
}
Try it!

SPARQL - Katzen mit einem WP-Artikel auf deutsch

[edit]

Mit Hilfe der Syntax schema:about werden Wikipedia-Artikel angezeigt 

#Katzen mit deutschen WP-Artikeln
SELECT ?katze ?katzeLabel ?katzeDescription ?article
WHERE 
{
  ?katze     wdt:P31        wd:Q146  .
  ?article   schema:about   ?katze   .
  ?article   schema:inLanguage 'de'  .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

SPARQL - Wartung Wikidata, Liste der deutschen Bundesländer

[edit]
# Liste der Bundesländer von Deutschland
SELECT ?bundesland ?bundeslandLabel WHERE {
  ?bundesland wdt:P17 wd:Q183.
  ?bundesland wdt:P31 wd:Q1221156.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

SPARQL - Wartung Wikidata, Anzahl Items direkt im Bundesland Bayern, gruppiert

[edit]
  1. Pro Objekttyp, also der Eigenschaft P31 (ist ein) wird die Anzahl von Items ermittelt,
  2. die direkt im Bundesland (Bayern=Q980, Hessen=Q1199, etc.) liegen.
SELECT ?objectType ?objectTypeLabel ?anz WHERE {
  {
    SELECT ?objectType (COUNT(?item) as ?anz)
    WHERE
        {
          ?item wdt:P17 wd:Q183.
          ?item wdt:P31 ?objectType .
          ?item wdt:P131 wd:Q980
          }
          GROUP BY ?objectType
    }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
} ORDER BY DESC(?anz)
Try it!

SPARQL - Wartung Wikidata, Item direkt im Bundesland

[edit]

Dies entspricht der Arbeitsliste Benutzer:Holger1959/BW-1 (Teilbereich) 

SELECT ?item ?itemLabel ?commonskat  # Liste der ausgegebenen Variablen
WHERE 
{
  ?item wdt:P31  wd:Q16970  .  # Haus ist ein Kirche=Q16970; Burg=Q23413; Burgruine=Q17715832
  ?item wdt:P17  wd:Q183    .  # Haus liegt im Staat Deutschland
  ?item wdt:P131 wd:Q985    .  # Haus liegt in Baden-Wuertemberg, Q1198 =NRW
  ?item wdt:P373 ?commonskat.  # haus hat commons-kategorie

  FILTER NOT EXISTS { ?item wdt:P18 ?bild }           # kein Bild vorhanden
  FILTER NOT EXISTS { ?item wdt:P625 ?koordinate }    # ohne Koordinate
    
  # dieser SERVICE erzeugt die Ausgabe von ?itemLabel (also dem Namen vom item),
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

SPARQL - label in Deutsch und Englisch

[edit]
  1. List of countries in English and German
SELECT ?country ?label_en ?label_de
WHERE
{
    ?country wdt:P31 wd:Q6256.
    ?country rdfs:label ?label_en filter (lang(?label_en) = "en").
    ?country rdfs:label ?label_de filter (lang(?label_de) = "de").
}
Try it!


oder so mit der description 

# Wikidata-Items in einem Ort mit Label und Description in meheren Sprachen gleichzeitig 
SELECT ?item ?deLabel ?enDesc ?deDesc WHERE {
  ?item wdt:P31 wd:Q3914;
    wdt:P17 wd:Q183;
    wdt:P131 wd:Q7022.
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
    ?item rdfs:label ?enLabel;
      schema:description ?enDesc.
  }
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de".
    ?item rdfs:label ?deLabel;
      schema:description ?deDesc.
  }
}
Try it!

SPARQL - Wartung Wikidata, Landkreis Ludwigsburg

[edit]

Dies entspricht der Arbeitsliste Benutzer:Holger1959/BW-LB 

SELECT ?item ?itemLabel ?article ?typLabel ?ortLabel ?commonskat ?bild ?coordinate WHERE { 
?item (wdt:P131 | wdt:1001) ?sub0 . 
  ?tree0 (wdt:P150)* ?sub0 . 
  ?tree0 (wdt:P131)* wd:Q8541 .   # Q8541 = Landkreis LB
  OPTIONAL { ?article   schema:about   ?item   . ?article   schema:inLanguage 'de'  } .   # deutschsprachige Wikipediaseite
   OPTIONAL {?item wdt:P373 ?commonskat } .  # item hat commons-kategorie
   OPTIONAL {?item wdt:P18 ?bild } .
   ?item wdt:P31 ?typ .
   OPTIONAL { ?item wdt:P131 ?ort } .
   OPTIONAL { ?item wdt:P625 ?coordinate } .
  MINUS{ ?item wdt:P31  wd:Q21573182} # Ohne (Naturdenkmal in Deutschland)
  
   # dieser SERVICE erzeugt die Ausgabe von ?itemLabel (also dem Namen vom item),
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
} ORDER BY DESC(?typLabel)
Try it!

SPARQL - Wartung Wikidata, Anzahl der Items direkt in einem Bundesland

[edit]

Die entspricht der Arbeitsliste Benutzer:Holger1959/BW-1 Spezielles zum Weitersortieren: noch direkt „in <Bundesland>“ Bei etwas mehr als ca. 5000 oder 6000 Einträgen wird die Wartungsliste vom Listeria-Bot nicht mehr aktualisiert. Stand Januar 2023: Bayern:11179, Hessen:6112, Niedersachsen:6033, Rheinland-Pfalz: 5061, alle Anderen weniger als 5000. 

SELECT ?bundesland ?bundeslandLabel ?anz WHERE {
  {
    SELECT ?bundesland (COUNT(?item) as ?anz)
    WHERE
        {
          ?bundesland wdt:P17 wd:Q183.
          ?bundesland wdt:P31 wd:Q1221156.
          ?item wdt:P17 wd:Q183;
          wdt:P131 ?bundesland .
          }
          GROUP BY ?bundesland
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
} ORDER BY DESC(?anz)
Try it!

SPARQL - weibliche Absolventen der Uni Leipzig mit Bild (Timeline)

[edit]

Datenbankabfrage, die uns eine Liste aller weiblichen Absolventen einer vorgegebenen Hochschule liefert. Von den so gefundenen Personen suchen wir zusätzlich das Geburtsdatum, den Geburtsort und ein Bild. Als Ergebnis sehen wir dann die Geburtsorte als Markierungen auf einer Landkarte. Ein Mausklick auf eine Markierung zeigt das Bild der Frau. Die Bilder der gefundenen Personen können in einer Zeitleiste chronologisch nach ihrem Geburtsdatum angezeigt werden. (Frauen ohne Bild fehlen in dieser Auswertung.) 


#Ausgabe aller weiblichen Absolventinnen der Uni Leipzig mit Bild als Timeline, Map oder Liste
  #defaultView:Timeline 
  SELECT ?person ?personLabel ?coordinates ?birthDate ?birthPlaceLabel ?image # ausgegebene Variablen
  WHERE {
     ?person     wdt:P69  wd:Q154804   .  # ?person besuchte Bildungseinrichtung Uni Leipzig
     ?person     wdt:P21  wd:Q6581072  .  # ?person hat Geschlecht weiblich
     ?person     wdt:P19  ?birthPlace  .  # ?person hat Geburtsort ?birthPlace
     ?birthPlace wdt:P625 ?coordinates .  # ?birthPlace hat Koordinaten  ?coordinates
     ?person     wdt:P569 ?birthDate   .  # ?person hat Geburtsdatum  ?birthDate
     ?person     wdt:P18  ?image       .  # ?person hat Bild ?image  
     SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

SPARQL - Städte in den USA, deren Einwohnerzahl per Referenz belegt ist

[edit]
  1. The prefix p: points not to the object, but to a statement node. This node then is the subject of other triples.
  2. The prefix ps: within the statement node retrieves the object.
  3. The prov:wasDerivedFrom within the statement node points to a new reference node.
  4. The prefix pr: within the reference node retrieves the reference information.
  5. Siehe: https://en.wikibooks.org/wiki/SPARQL/WIKIDATA_Qualifiers,_References_and_Ranks
SELECT ?town ?townLabel ?anzahl  ?ref ?refLabel ?county ?countyLabel
  WHERE
  {
     ?town wdt:P31 wd:Q1093829   .   # ?town ist eine City in den Vereinigten Staaten
     ?town wdt:P131 ?county      .   # ?town liegt in der Verwaltungseinheit ?county
     ?town p:P1082 ?statement    .   # ?town hat ?statement
     ?statement ps:P1082 ?anzahl .   # ?statement hat Einwohner ?anzahl
     ?statement prov:wasDerivedFrom ?refnode.   # points to a new reference node.
     ?refnode   pr:P248 ?ref     .   #  ?refnode hat die Referenz ?ref
     SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
Try it!

SPARQL - weibliche Komponisten deren Geburtsdatum per Referenz belegt ist

[edit]
SELECT ?komponist ?komponistLabel ?geburtsdatum ?ref ?refLabel WHERE {
     ?komponist wdt:P106 wd:Q36834 .   # Beruf: Komponist
     ?komponist wdt:P21 wd:Q6581072 .  # hat Geschlecht: weiblich
     ?komponist p:P569 ?statement    .   # ?komponist hat ?statement
     ?statement ps:P569 ?geburtsdatum .   # ?statement geboren am  ?geburtsdatum
     ?statement prov:wasDerivedFrom ?refnode.   # points to a new reference node.
     ?refnode   pr:P248 ?ref     .   #  ?refnode hat die Referenz ?ref

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }  # labels in English
}
Try it!

SPARQL - ermittelt alle Items in der Verwaltungseinheit Q1741 ohne Objekttyp

[edit]

Es wird, falls vorhanden, die zugehörige Wikipediaseite und das Bild angezeigt, etwa analog zu https://de.wikipedia.org/wiki/Benutzer:Holger1959/BW-2 

SELECT ?item ?itemLabel ?article ?bild 
WHERE { 
      ?item wdt:P131 wd:Q1741 .            # liegt in der Verwaltungseinheit Q1741=Wien
      OPTIONAL { ?item wdt:P18 ?bild } .   # hat das Bild ?bild
      OPTIONAL { ?article   schema:about   ?item   . ?article   schema:inLanguage 'de'  } .   # deutschsprachige Wikipediaseite
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }      # ermittelt itemLabel
      FILTER NOT EXISTS { ?item wdt:P31 ?dummy }    # der Objekttyp existiert nicht
}
Try it!

SPARQL - ermittelt alle Items im Land(P17) Deutschland=Q183 mit englischen WikiVoyage-Artikel

[edit]
# englischsprachige Wikivoyage - Artikel im Land Deutschland
# und deren Koordiante, damit die Darstellung als Karte möglich ist 
SELECT ?item ?itemLabel ?article ?coordinate WHERE {
  ?item wdt:P17 wd:Q183 ;
    wdt:P625 ?coordinate .
  ?article schema:about ?item ;
    schema:inLanguage "en" ;
    schema:isPartOf <https://en.wikivoyage.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

SPARQL - ermittelt alle Items im Land(P17) Deutschland=Q183 mit deutschem WikiVoyage-Artikel

[edit]
# deutsche Wikivoyage - Artikel im Land Deutschland (=Q183) oder Frankreich=Q142
# und deren Koordiante, damit die Darstellung als Karte möglich ist 
#defaultView:Map
SELECT ?item ?itemLabel ?article ?coordinate WHERE {
  ?item wdt:P17 wd:Q183 ;  # Land (Q183=Deutschland, Q142=Frankreich, etc.)  
    wdt:P625 ?coordinate .
  ?article schema:about ?item ;
    schema:isPartOf <https://de.wikivoyage.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

SPARQL - ermittelt alle Items im Land Q142 mit deutschem WP-Artikel, ohne Objekttyp die keine Unterklasse sind

[edit]
SELECT ?item ?itemLabel ?article ?bild 
WHERE { 
     
      ?item wdt:P17 wd:Q142 .     # im Land Frankreich
      OPTIONAL { ?item wdt:P18 ?bild } .   # hat das Bild ?bild
      ?article   schema:about   ?item   . ?article   schema:inLanguage 'de'  .   # deutschsprachige Wikipediaseite
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }      # ermittelt itemLabel
      FILTER NOT EXISTS { ?item wdt:P31 ?dummy }    # der Objekttyp existiert nicht
      FILTER NOT EXISTS { ?item wdt:P279 ?dummy2 }  # ist keine Unterklasse von irgendetwas
}
Try it!


deutsche Wikivoyage-Artikel in BBOX (Schweiz)

[edit]
#defaultView:Map{"hide":["?item", "?coordinate"]}
#title:Wikivoyage-Artikel in BBOX (Schweiz)
SELECT ?image ?item ?itemLabel ?article ?coordinate
WITH {
  SELECT ?item ?itemLabel ?article (SAMPLE(?image_) AS ?image)
  WHERE {
    ?article schema:about ?item.
    ?article schema:name ?itemLabel.
    ?article schema:isPartOf <https://de.wikivoyage.org/> .
    OPTIONAL {
      ?item wdt:P18 ?image_.
    }
  }
  GROUP BY ?item ?itemLabel ?article ?coordinate
} AS %sub
WHERE {
  INCLUDE %sub
  SERVICE wikibase:box {
    ?item wdt:P625 ?coordinate.
    bd:serviceParam wikibase:cornerSouthWest "Point(5.9559 45.818)"^^geo:wktLiteral.
    bd:serviceParam wikibase:cornerNorthEast "Point(10.4921 47.8084)"^^geo:wktLiteral.
  }
}
ORDER BY ?itemLabel
LIMIT 2500
Wikivoyage-Artikel in BBOX (Schweiz)

SPARQL - Abfragen mit Rang

[edit]

-- Hilfe https://www.wikidata.org/wiki/Help:Ranking/de

SPARQL - ermittelt alle Einwohnerzahlen im Ort Q79580 zu allen Jahreszahlen mit dem jeweiligen Rang

[edit]
SELECT * 
{ wd:Q79580 p:P1082 ?st . 
  ?st ps:P1082 ?value . 
  ?st wikibase:rank ?rank . 
  ?st pq:P585 ?date . }
Try it!

SPARQL - ermittelt alle Einwohnerzahlen im Ort Q79580 zum bevorzugten Rang

[edit]
SELECT * { wd:Q79580 p:P1082 ?st . 
          ?st ps:P1082 ?einwohnerzahl . 
          ?st wikibase:rank wikibase:PreferredRank  . 
          ?st pq:P585 ?date . 
 
 }
Try it!

SPARQL - ermittelt Einwohnerzahlen von Q1093829= "City in den Vereinigten Staaten" mit bevorzugtem Rang

[edit]
# Es werden nur Orte mit einem bevorzugtem Rang und die Jahreszahl hierzu angezeigt.
# Eigentlich sollte nach vollständiger Erfassung der Einwohnerzahlen vom Census 2020 
# der bevorzugte Rang auch immer die Einwohnerzahl vom Jahr 2020 sein und nicht fälschlicherweise von einem 
# anderen Jahr. 
SELECT ?town ?townLabel  ?anzahl ?date
  WHERE
  {
     ?town wdt:P31 wd:Q1093829   .   # ?town ist eine City in den Vereinigten Staaten 
     ?town p:P1082 ?statement    .   # ?town hat ?statement
     ?statement ps:P1082 ?anzahl .   # ?statement hat Einwohner ?anzahl
     ?statement wikibase:rank wikibase:PreferredRank  .
     ?statement pq:P585 ?date . 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  } ORDER BY ?date
Try it!

SPARQL - ermittelt Einwohnerzahlen von Q1093829= "City in den Vereinigten Staaten" mit bevorzugtem Rang

[edit]
# Es werden nur Orte mit einem bevorzugtem Rang im Jahr 2020 angezeigt (nur etwa 223 am 24.1.2022)
# oder alternativ die Orte zu einem anderen Jahr (408 am 24.1.2022, FILTER(YEAR(?date) < 2020)) 

SELECT ?town ?townLabel  ?anzahl ?date 
  WHERE
  {
     ?town wdt:P31 wd:Q1093829   .   # ?town ist eine City in den Vereinigten Staaten 
     ?town p:P1082 ?statement    .   # ?town hat ?statement
     ?statement ps:P1082 ?anzahl .   # ?statement hat Einwohner ?anzahl
     ?statement wikibase:rank wikibase:PreferredRank  .
     ?statement pq:P585 ?date . 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    FILTER(YEAR(?date) = 2020)   # zum Jahr 2020
    # FILTER(YEAR(?date) < 2020)  # zu einem anderen Jahr
  }
Try it!

SPARQL-Einwohnerzahlen USA nach Jahreszahlen gruppiert

[edit]
# Diese Abfrage selektiert für alle Orte in den Vereinigten Staaten die Jahreszahl zu der die Einwohnerzahl ermittelt worden ist.
# Die Anzahl der Orte wird pro Jahreszahl aufsummiert.
# Lesebeispiel des Abfrageergebnisses:
# Die Einwohnerzahl eines Datensatzes (=Ort) ist vom Jahr 1698 .
# Die Einwohnerzahl von 24587 Datensätzen (=Orten) ist vom Jahr 2010.
# Die Einwohnerzahl von 852   Datensätzen (=Orten) ist vom Jahr 2020. (Stand 16.1.2022)  
#
SELECT ?year (COUNT (DISTINCT ?statement) AS ?countTownInUSA) WHERE {
  
     VALUES ?itemList {wd:Q3327870 wd:Q498162 wd:Q15127012 wd:Q1093829 }  
     ?town wdt:P31 ?itemList     .   # ?town ist eine City in den Vereinigten Staaten, Town, etc. 
     ?town p:P1082 ?statement    .   # ?town hat ?statement
     ?statement ps:P1082 ?anzahl .   # ?statement hat Einwohner ?anzahl
#     ?statement wikibase:rank wikibase:PreferredRank  .
     ?statement pq:P585 ?date .

   BIND(year(?date) AS ?year)
} GROUP BY ?year
ORDER BY ?year
Try it!

SPARQL- Ort zur deutschen Postleitzahl

[edit]
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P17  wd:Q183 . # liegt in Deutschland
  ?item wdt:P281 '70734' . # hat Postleitzahl
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". } 
}
Try it!

SPARQL - Links

[edit]
WikiData Einführung-de
Vortrag zum Wikidata Query Service auf deutsch
A Gentle Introduction to Wikidata for Absolute Beginners (including non-techies!)

-- englische Originalseite: Wikidata:SPARQL_query_service/queries

-- Wikidata:Einführung (deutsch): Wikidata:Introduction/de

-- SPARQL Tutorial (der Anfang ist auf deutsch) Wikidata:SPARQL_tutorial/de

-- SPARQL (englisches WIKIBOOK) englisches WIKIBOOK 

Video: Asaf Bartov: A Gentle Introduction to Wikidata for Absolute Beginners (englisch)
Video: Querying Wikidata with SPARQL for Absolute Beginners (englisch)

-- Französisch: User:Simon_Villeneuve/SPARQL

-- Wikipedia: w: SPARQL

See: https://tools.wmflabs.org/wdq2sparql/w2s.php,

  1. https://query.wikidata.org interaktiv Abfragen durchführen

Requests_for_deletions und MergeItems

[edit]

github-wikidata-bot

[edit]

-- https://www.wikidata.org/wiki/User_talk:Konstin

-- https://github.com/konstin/github-wikidata-bot/releases

-- https://gist.github.com/konstin/9b90ae895ad9a270102415474a56e613 logfile

vorhandene Wikidata-Infos, per ListeriaBot erzeugt

[edit]
  1. -- https://de.wikipedia.org/wiki/Benutzer:Aeroid/List_DE_NI_Immediate Benutzer:Aeroid/List_DE_NI_Immediate in der deutschen Wikipedia
  2. -- https://de.wikipedia.org/wiki/Benutzer:Holger1959/BW-WN Benutzer:Holger1959/BW-WN in der deutschen Wikipedia (wurde gelöscht)
  3. -- https://de.wikipedia.org/wiki/Benutzer:Triplec85/BW-TBB-Gr%C3%BCnsfeld oder hier
  4. -- https://de.wikipedia.org/wiki/Benutzer:Holger1959 Homepage
  5. -- https://www.wikidata.org/wiki/User:ListeriaBot ListeriaBot
  6. -- https://en.wikipedia.org/wiki/Template:Wikidata_list Doku en
  7. -- https://de.wikipedia.org/wiki/Vorlage:Wikidata_list Doku de
  8. -- http://magnusmanske.de/wordpress/?p=301 Markus Manske Blog
  9. -- https://bitbucket.org/magnusmanske/listeria/src/master/ Quellcode
  10. -- https://tools.wmflabs.org/listeria/botstatus.php#dewiki Status vom Bot (Liste der mit ausgeführten Abfragen)

WikiProjects

[edit]
  1. -- https://www.wikidata.org/wiki/Category:Geographical_WikiProjects
  2. -- Wikidata:WikiProject Italy
  3. -- Wikidata:WikiProject France
  4. -- Wikidata:WikiProject Spain
  5. -- Wikidata:WikiProject Danmark
  6. -- Wikidata:WikiProject Greece
Retrieved from "https://www.wikidata.org/w/index.php?title=User:MTheiler&oldid=2137582562"