Engineering Equation

Solver (EES) Functions

and Procedures for
Forced convection heat
transfer calculations:
by
Dr. M. Thirumaleshwar
formerly:
Professor, Dept. of Mechanical Engineering,
St. Joseph Engg. College, Vamanjoor,
Mangalore,
India
Preface:
This file contains notes on Engineering
Equation Solver (EES) Functions and
Procedures for Forced convection heat
transfer calculations. Some problems are also
included.
These notes were prepared while teaching Heat
Transfer course to the M.Tech. students in
Mechanical Engineering Dept. of St. Joseph
Engineering College, Vamanjoor, Mangalore,
India.
It is hoped that these notes will be useful to
teachers, students, researchers and
professionals working in this field.
For students, it should be particularly useful to
study, review the subject and solve the home-
work problems.
• M. Thirumaleshwar
• August 2016
References:
1. M. Thirumaleshwar: Fundamentals of Heat & Mass Transfer, Pearson
Edu., 2006. See: https://books.google.co.in/books?id=b2238B-
AsqcC&printsec=frontcover&source=gbs_atb#v=onepage&q&f=false

• 2. Cengel Y. A. Heat Transfer: A Practical Approach, 2nd Ed. McGraw Hill

Co., 2003

• 3. Cengel, Y. A. and Ghajar, A. J., Heat and Mass Transfer - Fundamentals

and Applications, 5th Ed., McGraw-Hill, New York, NY, 2014.

• 4. Incropera , Dewitt, Bergman, Lavine: Fundamentals of Heat and Mass

Transfer, 6th Ed., Wiley Intl.

• 5. M. Thirumaleshwar: Software Solutions to Problems on Heat Transfer –

Convection – Part-I- Forced convection - 2013

• http://bookboon.com/en/software-solutions-to-problems-on-heat-
transfer-iv-ebook

• 6. Frank Kreith and Mark S Bohn: Principles of Heat Transfer, PWS Publ.
Co. (Intl. Thomson Publ.), 5th Ed., 1997
EES Functions and Procedures for Forced
convection heat transfer calculations:
Contents:
Forced convection – Tables of formulas
Boundary layer, flow over flat plates, across cylinders, spheres
and tube banks –
Flow inside tubes and ducts
A. Forced convection formulas:
Flow across circular and non-circular cylinders: (Ref: Cengel)
Flow across Tube banks:
For Turbulent flow:
For smooth tubes: First Petukhov eqn:

Chilton-Colburn Analogy:

For smooth tubes:

For more accuracy, use Second Petukhov eqn:

For rough tubes: Colebrook eqn for friction factor:

Chilton-Colburn Analogy:
B. Forced Convection: EES Procedures:

"Forced convection - Air on Flat Plates:"

PROCEDURE ForcedConv_Air_FlatPlate (P_infinity, T_infinity, U_infinity, Re_c, x, W, T_s: xc, Re_x,

delta_h, delta_t, h_x, h_avg,Cf_x, Cf_a, Q, tau_s, F_D)

"Finds various quantities for laminar flow of Air over a Flat Plate:"

"Inputs: Pa, C, m/s, m"

"Outputs: m, W/m^2.C, W, N/m^2, N"

T_f := (T_infinity + T_s)/2 " mean film temp, C"

"Properties of Air (Ideal gas) at T_f:"

rho:=Density(Air,T=T_f,P=P_infinity)
cp:=Cp(Air,T=T_f)
mu:=Viscosity(Air,T=T_f)
k:=Conductivity(Air,T=T_f)
Pr:=Prandtl(Air,T=T_f)

xc := Re_c * mu/ (rho * U_infinity) "m....critical distance"

IF (xc < 0.95*x) then CALL ERROR (' xc < 0.95 x, Use Mixed b.l. equations, xc (m)= xxxF4 ', xc)

Re_x := (rho * x * U_infinity)/mu " Finds Reynolds No."

delta_h := 5 * x/ sqrt(Re_x) "hydrody. boundary layer thickness, m"

delta_t := delta_h / Pr^(1/3) "thermal boundary layer thickness, m"
Cf_x := 0.664 / sqrt(Re_x) "local friction coeff."
Cf_a := 2 * Cf_x "Average friction coeff."
tau_s := Cf_a * rho * U_infinity^2/2 " Finds avg shear stress, N/m^2"
h_x := 0.332 * (k / x) * sqrt(Re_x) * Pr^(1/3) "local heat tr coeff., W/m^2 C"
h_avg := 2 * h_x "average heat tr coeff., W/m^2 C"
Q := h_avg * ( x * W) * (T_s - T_infinity) " heat transfer over the area (x * W) , W"
F_D := tau_s * (x * W) " Shear force acting on area (x * W), N"

END

"====================================================================="

PROCEDURE ForcedConv_Air_FlatPlate_mixed (P_infinity, T_infinity, U_infinity,Re_c, L, W, T_s: Re_L,

xc, h_lam_avg,h_turb_avg, h_plate_avg, CfL_avg, Q_lam,Q_turb,Q_tot, F_D)

"Finds various quantities for laminar flow of Air over a Flat Plate:"

"Inputs: Pa, C, m/s, m"

"Outputs: m, W/m^2.C, W, N/m^2, N"

T_f := (T_infinity + T_s)/2 " mean film temp, C"

"Properties of Air (Ideal gas) at T_f:"

rho:=Density(Air,T=T_f,P=P_infinity)
cp:=Cp(Air,T=T_f)
mu:=Viscosity(Air,T=T_f)
k:=Conductivity(Air,T=T_f)
Pr:=Prandtl(Air,T=T_f)

xc := Re_c * mu/ (rho * U_infinity) "m....critical distance"

IF (xc >= 0.95*L) then CALL ERROR (' xc > 0.95 L, Use Laminar flow equations, xc= xxxF4 ', xc)

Re_L := (rho * L * U_infinity)/mu " Finds Reynolds No."_

"Ref: HMT by Domkundwar, pp. 12.52:"

h_lam_avg := (k / xc) * 0.664 *(Re_c)^(1/2) * Pr^(1/3) " finds avg h for lam region"
Q_lam := h_lam_avg * (W * xc) * (T_s - T_infinity) "W....heat tr in lam region"

h_turb_avg :=((k * 0.036)/(L - xc)) * (Re_L^0.8 - Re_c^0.8) * Pr^(1/3) " finds avg h for turb region"

Q_turb := h_turb_avg * (W * (L - xc)) * (T_s - T_infinity) "W....heat tr in turb region"

Q_tot := Q_lam + Q_turb " W....total heat tr"

"Ref: Incropera, 5th Ed., pp. 396:"

A := 0.037 * Re_c^0.8 - 0.664 * Re_c^0.5

h_plate_avg := (k/L) * (0.037 * Re_L^0.8 - A) * Pr^(1/3)

Q_plate_tot := h_plate_avg * (L * W) * (T_s - T_infinity) "W.... Qtot by second method"

CfL_avg := (0.074/Re_L^(1/5)) - (1742/Re_L) " finds avg Cf over the plate"

F_D := (CfL_avg * rho * U_infinity^2/2 ) * ( L * W) "N....Drag force on plate"

END

"====================================================================="

PROCEDURE ForcedConv_Air_AcrossCylinder (P_infinity, T_infinity, U_infinity, L, D, T_s: Re_D,

Nusselt_D_bar, h_bar, Q)

"Ref: Incropera, 5th Ed. pp. 411, Eqn. (7.57)"

"Churchill and Bernstein eqn....for entire range of Re_D and a wide range of Pr"

"Finds various quantities for flow of Air across a cylinder:"

"Inputs: Pa, C, m/s, m"

"Outputs: W/m^2.C, W, W"

T_f := (T_infinity + T_s)/2 " mean film temp, C"

"Properties of Air (Ideal gas) at T_f:"

rho:=Density(Air,T=T_f,P=P_infinity)
{cp:=Cp(Air,T=T_f)}
mu:=Viscosity(Air,T=T_f)
k:=Conductivity(Air,T=T_f)
Pr:=Prandtl(Air,T=T_f)
cp:=SpecHeat(Air,T=T_f)

Re_D := D * U_infinity * rho/mu "Finds Reynolds No."

"To find h accurately: Use Churchill and Bernstein eqn."

Nusselt_D_bar := 0.3 + ((0.62 * Re_D^0.5 * (Pr)^(1/3))/(1 + (0.4/Pr)^(2/3))^(1/4)) * (1 +

(Re_D/282000)^(5/8))^(4/5)
h_bar :=Nusselt_D_bar * k / D "Finds h_bar"
Q := h_bar * (pi * D * L) * (T_s - T_infinity) "W.... heat tr"

END

"======================================================================"

PROCEDURE FC_Air_AcrossCylinder_Hilpert (P_infinity, T_infinity, U_infinity, L, D, T_s: Re_D,

Nusselt_D_bar, h_bar, Q)

"Ref: Incropera, 5th Ed. pp. 410, Eqn. (7.55-b)"

"Hilpert eqn....for gases"

"Finds various quantities for Forced Conv (FC) of Air across a cylinder:"

"Inputs: Pa, C, m/s, m"

"Outputs: W/m^2.C. W, W"

T_f := (T_infinity + T_s)/2 " mean film temp, C"

"Properties of Air (Ideal gas) at T_f:"

rho:=Density(Air,T=T_f,P=P_infinity)
{cp:=Cp(Air,T=T_f)}
mu:=Viscosity(Air,T=T_f)
k:=Conductivity(Air,T=T_f)
Pr:=Prandtl(Air,T=T_f)
cp:=SpecHeat(Air,T=T_f)

Re_D := D * U_infinity * rho/mu "Finds Reynolds No."

"To find h_bar: Use Hilpert eqn."

IF (0.4 <= Re_D ) and (Re_D <= 4) Then

C := 0.989
m := 0.33
ELSE
IF ( 4 < Re_D ) and (Re_D <= 40) Then
C := 0.911
m := 0.385
ELSE
IF ( 40 < Re_D ) and (Re_D <= 4000) Then
C := 0.683
m := 0.466
ELSE
 IF ( 4000 < Re_D ) and (Re_D <= 40000) Then
C := 0.193
m := 0.618
ELSE
IF ( 40000 <Re_D ) and (Re_D <=400000) Then
C := 0.027
m := 0.805
EndIf
EndIf
EndIf
EndIf
EndIf

Nusselt_D_bar := C * Re_D^m * Pr^(1/3) " Finds avg. Nusselts No."

h_bar :=Nusselt_D_bar * k / D "Finds h_bar"
Q := h_bar * (pi * D * L) * (T_s - T_infinity) "W.... heat tr"

END

"=========================================================="

PROCEDURE FC_Air_AcrossSphere_Whitaker (P_infinity, T_infinity, U_infinity, D, T_s: Re_D,

Nusselt_D_bar, h_bar, Q)

"Ref: Incropera, 5th Ed. pp. 415, Eqn. (7.59)"

"Whitaker eqn....for 0.71 < Pr < 380 and 3.5 < Re_D < 7.6 e04"

"Finds various quantities for Forced Convection (FC) of Air across a Sphere:"

"Inputs: Pa, C, m/s, m"

"Outputs: W/m^2.C. W, W"

"Properties of Air (Ideal gas) at T_infinity:"

rho:=Density(Air,T=T_infinity,P=P_infinity)
{cp:=Cp(Air,T=T_f)}
mu:=Viscosity(Air,T=T_infinity)
mu_s := Viscosity(Air,T=T_s) "....mu_s at T_s"
k:=Conductivity(Air,T=T_infinity)
Pr:=Prandtl(Air,T=T_infinity)
cp:=SpecHeat(Air,T=T_infinity)

Re_D := D * U_infinity * rho/mu "Finds Reynolds No."

If (Re_D < 3.5) or (Re_D > 7.6e04) Then CALL WARNING (' The results may not be accurate since 3.5 <
Re_D < 7.6e04 does not hold. Re_d = XXXA1', Re_D)

If (Pr < 0.71) or (Pr > 380) Then CALL WARNING (' The results may not be accurate since 0.71 < Pr <
380 does not hold. Pr = XXXA1', Pr)

"To find h_bar: Use Whitaker eqn."

Nusselt_D_bar := 2 + (0.4 * Re_D^(1/2) + 0.06 * Re_D^ (2/3)) * Pr^0.4 * (mu/mu_s)^(1/4) " Finds avg.
Nusselts No."
h_bar :=Nusselt_D_bar * k / D "Finds h_bar"
Q := h_bar * (pi * D^2) * (T_s - T_infinity) "W.... heat transfer"

END

"=========================================================="

"Functions for Nusselts No. for cross flow across Tube bank with In-line and Staggered
arrangements:"

Function NUSSELT_TubeBank_In_line(Re_D, Pr, Pr_s)

If (Re_D <= 100) Then

NUSSELT_TubeBank_In_line:= 0.9 * Re_D^0.4 * Pr^0.36 * (Pr / Pr_s)^0.25
Else
If (Re_D > 100) And (Re_D <=1000) Then
NUSSELT_TubeBank_In_line := 0.52 * Re_D^0.5 * Pr^0.36 * (Pr / Pr_s)^0.25
Else
If (Re_D > 1000) And (Re_D <=2E05) Then
NUSSELT_TubeBank_In_line := 0.27 * Re_D^0.63 * Pr^0.36 * (Pr / Pr_s)^0.25
Else
If (Re_D > 2E05) And (Re_D <=2E06) Then
NUSSELT_TubeBank_In_line := 0.033 * Re_D^0.8 * Pr^0.4 * (Pr / Pr_s)^0.25
Else
Call Error (' Re_D must be between 0 and 2E06 !!')
EndIf
EndIf
EndIf
EndIf
End

"-----------------------------------------------------------------------"

Function NUSSELT_TubeBank_Staggered(Re_D, Pr, Pr_s,S_T,S_L)

If (Re_D <= 500) Then

NUSSELT_TubeBank_Staggered= 1.04 * Re_D^0.4 * Pr^0.36 * (Pr / Pr_s)^0.25
Else
If (Re_D > 500) And (Re_D <=1000) Then
NUSSELT_TubeBank_Staggered:= 0.71 * Re_D^0.5 * Pr^0.36 * (Pr / Pr_s)^0.25
Else
If (Re_D > 1000) And (Re_D <=2E05) Then
NUSSELT_TubeBank_Staggered:= 0.35 * (S_T / S_L)^0.2 * Re_D^0.6 * Pr^0.36 * (Pr /
Pr_s)^0.25
Else
If (Re_D > 2E05) And (Re_D <=2E06) Then
NUSSELT_TubeBank_Staggered := 0.031 * (S_T / S_L)^0.2 * Re_D^0.8 *
Pr^0.36 * (Pr / Pr_s)^0.25
Else
Call Error (' Re_D must be between 0 and 2E06 !!')
EndIf
EndIf
EndIf
EndIf
End
"----------------------------------------------------------------------------"
"For In-line tube arrangement:

Correction Factor for N_L less than 14:

F_InLine=0.568730388 + 0.155621584*N_L - 0.0243568396*N_L^2 + 0.00178191834*N_L^3 -

0.0000490364034*N_L^4 "

"For Staggered tube arrangement:

Correction Factor for N_L less than 14:

F_staggered=0.47630486 + 0.191385976*N_L - 0.0289872621*N_L^2 + 0.00201365228*N_L^3 -

0.0000525013679*N_L^4 "

"-------------------------------------------------------------------------------"

"Correction Factors for In-Line tube banks, if the N_L, no. of rows in Longitudinal direction is less
than 14:"

"Curve-fit from EES:"

Function F_InLine (N_L)

If (N_L < 14) Then

F_InLine=0.568730388 + 0.155621584*N_L - 0.0243568396*N_L^2 + 0.00178191834*N_L^3 -

0.0000490364034*N_L^4

Else

F_InLine = 1

EndIf

End
"-------------------------------------------------------------------------------------"

"Correction Factors for Staggered tube banks, if the N_L, no. of rows in Longitudinal direction is
less than 14:"

"Curve-fit from EES:"

Function F_Staggered (N_L)

If (N_L < 14) Then

F_Staggered=0.47630486 + 0.191385976*N_L - 0.0289872621*N_L^2 + 0.00201365228*N_L^3 -

0.0000525013679*N_L^4

Else

F_Staggered = 1

EndIf
End
"=============================================================================="
PROCEDURE FC_Inside_Cyl(Fluid$, T_s, T_in, T_out, D,U : Re_D, Nusselt, h,Q, LMTD, L, f, DELTAP )

"Forced convection (FC) inside Cylinders, with Fluid$: Water or Air"

"Inputs: T_s (C), T_in, T_out (C), D (m), U (m/s)"

"Outputs: Re_D, Nusselt, h (W/m^2-C), Q (W), LMTD (C), L (m),f, DELTAP (Pa)"

T_b := (T_out+T_inf)/2 “bulk mean temp”

A_c = pi * D^2/4 “Area of cross-section”

IF (Fluid$ = 'Water') Then

k=Conductivity(Water,T=T_b,P=1.013e05)
rho=Density(Water,T=T_b,P=1.013e05)
mu=Viscosity(Water,T=T_b,P=1.013e05)
cp=SpecHeat(Water,T=T_b,P=1.013e05)
Pr=Prandtl(Water,T=T_b,P=1.013e05)
ELSE
IF (Fluid$ = 'Air') Then
beta := 1/(T_b + 273)
mu:=Viscosity(Air,T=T_b)
rho:=Density(Air,T=T_b,P=1e05)
nu := mu/rho
cp:=SpecHeat(Air,T=T_b)
k:=Conductivity(Air,T=T_b)
EndIF
EndIf

Re_D := D * U / nu
Pr := mu*cp/k

If (Re_D < 10000) Then CALL WARNING (' The results may not be accurate since Re_D > 10000 does
not hold. Re_D = XXXA1', Re_D)

If (Pr < 0.6) or (Pr > 160) Then CALL WARNING (' The results may not be accurate since 0.6 < Pr < 160
does not hold. Pr = XXXA1', Pr)

IF (T_in > T_out) Then

n = 0.3
ELSE
IF (T_in < T_out) Then
n = 0.4
ENDIF
ENDIF

Nusselt = 0.023 * Re^0.8 * Pr^n "finds Nusselts No."

h:= Nusselt * k / D "finds h"

DELTAT_in := T_s - T_in

DELTAT_out := T_s - T_out
LMTD: = (DELTAT_in - DELTAT_out) / ln(DELTAT_in/DELTAT_out) “Log Mean Temp Difference”
Q := rho * A_c * U * cp * (T_out - T_in) "finds Q, W"
L :=Q/ (h * (pi * d ) * LMTD) "by heat balance; finds L"

"Also, find the pressure drop:"

"Friction factor: Use the first Petukhov eqn, which is an explicit eqn. for f. Valid for Reynolds
Number range: Re = 3000 to 5E06"

f := (0.79 * ln(Re_D) - 1.64)^(-2) “…friction factor”

DELTAP := f * (L / D) * rho * U^2 / 2 "[N/m^2]"

END

“===========================================================================”

C. Forced convection: Problems:

C.1. Boundary layer fundamentals, Flow over flat plates, Momentum

– heat transfer analogy etc.:

"Prob. C.1.1 Dry air at atmospheric pressure and 20 C is flowing with a velocity of 3 m/s along the
length of a long flat plate, 0.3 m wide, maintained at 100 C. Calculate the following quantities at x = 0.3
m:
(i) Boundary layer thickness
(ii) Local friction coeff.
(iii) Avg. friction coeff.
(iv) Avg. shear stress due to friction
(v) Thickness of thermal boundary layer
(vi) Local conv. heat transfer coeff.
(vii) Rate of heat transfer from the platebetween x = 0 and x = x by convection, and
(viii) Drag force on the plate between x = 0 and x = 0.3 m

Also, find out the value of x_c , i.e. the distance along the length at which the flow turns turbulent (Re_c
= 5 x 10^5)

EES Solution:

“Data:”

P_infinity = 1.013e05 [Pa]

T_s = 100[C]
T_infinity = 20[C]
U_infinity = 3[m/s]
Re_c = 5e05
x = 0.3[m]
W = 0.3[m]

Call ForcedConv_Air_FlatPlate (P_infinity, T_infinity, U_infinity, Re_c, x, W, T_s: xc, Re_x, delta_h,
delta_t, h_x, h_avg,Cf_x, Cf_a, Q, tau_s, F_D)

Results:
Thus:

(i) Boundary layer thickness = δh = 0.006884 m … Ans.

(ii) Local friction coeff. = Cfx = 0.003047 … Ans.
(iii) Avg. friction coeff. = Cfa = 0.006095 … Ans.
(iv) Avg. shear stress due to friction = τs = 0.02905 N/m^2 … Ans.
(v) Thickness of thermal boundary layer = δt = 0.007681 m … Ans.
(vi) Local conv. heat transfer coeff. = hx = 6.069 W/m^2.C … Ans.
(vii) Rate of heat transfer from the plate betwn. x = 0 and x = x: Q = 87.39 W … Ans.
(viii) Drag force on the plate betwn. x = 0 and x = 0.3 m: FD = 0.002615 N .. Ans.

==============================================================================

Prob. C.1.2. A journal bearing has a clearance of 0.5 mm. The journal has a diameter of 100 mm and
rotates at 3600 rpm within the bearing. It is lubricated by an oil having a density of 800 kg/m^3, viscosity
of 0.01 kg/m.s, and a thermal cond. of 0.14 W/m.K. If both the journal and bearing temps are maintained
at 60 C, calculate the rate of heat transfer from the bearing and the power required for rotation per unit
length.
EES Solution:

"First write functions for temp distribution T(y) and first derivative of temp, i.e. dT/dy:"

Function T(y,mu,k,U,L,T_L,T_0)

T := T_0 + mu/(2 * k) * U^2 * ((y / L) - (y / L)^2) + (T_L - T_0) * (y / L)

end

Function dTbydy (y, mu, k, U, L, T_L, T_0)

dTbydy := (mu / (2 * k)) * U^2 * ( (1 / L) - 2 * y/ L^2) + (T_L - T_0) / L

end

"Data:"

D = 0.1 [m] "....dia of journal"

L = 0.5E-03 [m] "...distance between two parallel plates , idealizing the journal bearing as two plates, one
stationary and the other one moving"
U = (3600 / 60) * (pi * D) "[m/s]"
T_0 = 60 [C]
T_L = 60 [C]

"Properties of oil:"

rho = 800 [kg/m^3]

mu = 0.01 [kg/m-s]
k = 0.14 [W/m-C]

"Calculations:"

Heat transfer to the journal and bearing is given by Fourier's Law:

Q_journal = - k * (pi * (D + 2.L) * 1) * dTbydy_y=0, per unit length of journal

Q_bearing = - k * (pi * (D + 2.L) * 1) * dTbydy_y=L, per unit length of bearing"

Q_journal = - k * (pi * (D + 2 * L) *1) * dTbydy(0, mu, k, U, L, T_L, T_0) ".... W per unit length of journal"

Q_bearing = - k * (pi * (D + 2 * L) *1) * dTbydy(L, mu, k, U, L, T_L, T_0) ".... W per unit length of bearing"

Q_tot = abs(Q_journal) + abs(Q_bearing) "W/m length"

"Power to turn the journal:

This is equal to the Drag force multiplied by the velocity.

Drag force = shear stress * Area

Shear stress = tau = mu * dU/dy at y = 0

Area = p * D * L.

So, we get:"

P = (1/L) * pi * D * mu * U^2 "W per unit length of bearing"

Results:

Thus:

Heat transfer to journal = -1127 W/m (-ve sign indicating heat flow in –ve y direction, i.e. into the bottom
plate) …. Ans.

Heat transfer to bearing = 1127 W/m (+ve sign indicating heat flow in +ve y direction, i.e. into the top
plate) …. Ans.

Total heat transfer, Qtot = 2255 W/m …. Ans.

Mech. Power required to turn the bearing, P = 2232 W.

Note that Qtotal = P, as it should be. Small difference is due to the difference in surface areas of
journal and bearing.

===========================================================================
"Prob. C.1.3. Air at 20 C and atm pressure is flowing over a flat plate at a velocity of 3 m/s. If the plate
is 30 cm wide and at a temp. of 60 C, calculate: (a) thickness of velocity and thermal boundary layers (b)
local and average friction coeff. (c) local and average heat tr. coeff. (d) total drag force on the plate. Take
the following properties of air at 313 K:..[VTU-July/Aug. 2002]"
"Data:"

"Properties of Air at mean temp (T_f = 40 C = 313 K):"

rho = 1.18 [kg/m^3]

k = 0.0272 [W/m-C]
cp = 1007 [J/kg-C]
Pr = 0.705 [-]
nu = 17E-06 [m^2/s]

T_inf = 20[C]
T_s = 60 [C]
T_f = (T_inf + T_s) / 2
U_inf = 3[m/s]
L = 0.3[m]
W = 1[m]
P_1 = 1.013e05 [Pa]

"Calculations:"

Re_L = L * U_inf / nu "...Reynold's No. at the end of plate"

"We note that Re_L is 52941 < 5E05. Therefore, flow is laminar. Use correlations for laminar flow:"

delta_L = 5 * L / sqrt(Re_L) "thickness of velocity b.l."

delta_t = delta_L / Pr^(1/3) " thickness of thermal b.l."

Cf_L = 0.664 / sqrt(Re_L) "...local friction coeff. at end of plate"

Cf_avg = 2 * Cf_L "...average friction coeff. over the entire plate"

Nusselt_L = 0.332 * sqrt(Re_L) * Pr^(1/3) "...local Nusselt No. at end of plate"

Nusselt_L = h_L * L / k "...gives local heat tr coeff h_L at end of plate"

h_avg = 2 * h_L "gives avg heat tr coeff h_avg over entire plate"

Q = h_avg * ( L * W) * (T_s - T_inf) "[W] ... total heat tr from surface of plate"

tau = Cf_avg * rho * U_inf^2 / 2 "..shear stress, [N/m^2]"

F_D = tau * (L * W) "[N]...total drag force"

Results:
Required results are shown boxed in the above Table.
------------------------------------------------------------------------------------------------------------------

"Prob. C.1.4. Air at 200 C and velocity 5 m/s flows over a plate 1.5 m long. The plate is maintained at a
uniform temp of 100 C. The avg. heat transfer coeff is 7.5 W/m^2.K. Calculate the drag force exerted on
the plate per 0.75 m width by using Reynolds - Colburn analogy. - [VTU-May 2007]"

T inf
U inf
Ts
W
L

EES Solution:

"Data:"

T_s = 100[C]
T_inf = 200[C]
U_inf =5[m/s]
L = 1.5[m]
W = 0.75[m]
h_avg = 7.5[W/m^2-K]
T_f = (T_s + T_inf)/2

"Properties of Air at T_f:"

rho = Density(Air,T=T_f,P=1.013E05) "[kg/m^3]"

cp=Cp(Air,T=T_f) "[W/m-K]"
Pr=Prandtl(Air,T=T_f)

“Calculations:”

St = h_avg / (rho * U_inf * cp) "...Stanton No."

St * Pr^(2/3) = Cf / 2 "....Reynolds - Colburn Analogy .... finds Cf"
tau = Cf * rho * U_inf^2 / 2 "[N/m^2]..finds shear stress, tau"
F_D = tau * (L * W) "[N]...finds Drag force"

Results:

Thus:

The drag force = FD = 0.03285 N … Ans.

====================================================================
"Prob. C.1.5. Consider a rectangular fin that is used to cool a motor cycle engine. The fin is 0.15 m long
and at a temp of 250 C, while the motor cycle is moving at 80 km/h in air at 27 C. The air is in parallel
flow over both surfaces of the fin and turbulent flow conditions may be assumed to exist throughout. (a)
What is the rate of heat removal per unit width of fin? (b) Plot the heat removal rate per unit width of fin
for motor cycle speeds ranging from 10 to 100 km/h."[Ref:3]

T inf
U inf W
Ts

EES Solution:

"Data:"

T_inf = 27[C]
T_s = 250 [C]
T_f = (T_inf + T_s) / 2
U_inf_kmph = 80 [km/h]
U_inf_mps = U_inf_kmph*convert(km/h,m/s) "[m/s]"
L = 0.15[m]
W = 1[m]
P_1 = 1.013e05 [Pa]
"Properties of Air at mean temp (T_f = 277/2 = 138.5 C ):"

rho=Density(Air,T=T_f,P=P_1) "[kg/m^3]"
k=Conductivity(Air,T=T_f) "[W/m-C]"
cp=Cp(Air,T=T_f) "[J/kg-C]"
Pr=Prandtl(Air,T=T_f)
mu=Viscosity(Air,T=T_f) "[kg/m-s]"
nu = mu / rho "[m^2/s]"

"Calculations:"

Re_L = L * U_inf_mps / nu "...Reynold's No. at the end of plate"

"Using correlations for turb. flow:"

Nusselt_L_avg = 0.037 * (Re_L)^0.8 * Pr^(1/3) "...avg. Nusselt No. for entire plate in turb. flow"

Nusselt_L_avg= h_L_avg * L / k "...gives avg. heat tr coeff for entire plate"

Q = 2 * (h_L_avg * ( L * W) * (T_s - T_inf)) "[W] ... total heat tr from both surfaces of plate"

Results:

Note that Q = 5801 W for both surfaces of fin… Ans.

-------------------------------------------------------------------------------------------
To plot the graph of Q vs U_inf:
"Prob.C.1.6. Air at 30 C flows at a velocity of 45 m/s past a flat plate 50 cm long. The plate is maintained
at a uniform temp of 250 C. Find per metre width of plate: (i) the rate of heat transfer to the plate (ii) rate
of heat transfer from laminar portion of the plate (iii) rate of heat transfer from the turb. portion of the
plate. Assume a critical Reynolds No. of 5E05 (iv) What would be the error in the rate of heat transfer if
the boundary layer is assumed to be turbulent from the leading edge? [VTU-July / Aug. 2004]"

T inf
U inf Ts W

EES Solution:

"Data:"

T_s = 250[C]
T_inf = 30[C]
U_inf = 45[m/s]
L = 0.5[m]
W = 1[m]
T_f = (T_s + T_inf)/2
Re_cr = 5E05
P_1 = 101300 [Pa]

"Properties of Air:"

mu=Viscosity(Air,T=T_f)
rho = density(Air, T = T_f, P = P_1)
cp=Cp(Air,T=T_f)
k=Conductivity(Air,T=T_f)
Pr=Prandtl(Air,T=T_f)

"Calculations:"

Re_cr = U_inf * x_cr * rho / mu " finds x_cr.... the critical distance where transio from laminar to turb. flow
occurs"

"We observe that x_cr = 0.305 m. i.e. from the leading edge, upto a distance of 0.305 m, the flow is
laminar, and then from 0.305 up to 0.5 m the flow is turbulent. Use the relevant correlations to find heat
transfer in the two regions:"

"heat tr coeff in laminar region:"

h_x * x_cr / k = 0.332 * sqrt(Re_cr) * Pr^(1/3) " finds h_x"

h_lam_avg = 2 * h_x "Avg h for lam region"

Q_lam = (h_lam_avg * (W * x_cr) * (T_s - T_inf)) "W ... heat tr from lam region of plate; only top side of
plate is considered."

"heat transfer for turb region:"

"For Mixed boundary layer, we can also use the following relations for the entire plate:"

Re_L = U_inf * L * rho / mu

Nusselt_bar_L = (0.037 * Re_L^0.8 - A) * Pr^(1/3) "where...."

A =( 0.037 * Re_cr^0.8 - 0.664 * Re_cr^0.5)

"Therefore:"

h_L_avg * L / k = Nusselt_bar_L " ...finds h_L_avg for entire plate"

"And,"

Q_total = h_L_avg * (L * W ) * (T_s - T_inf) "[W] ... total heat tr rate from the entire plate"

"Therefore:"

Q_turb = Q_total - Q_lam "[W] .... heat tr from turb. region of plate"

"Alternatively: we can also use following eqns:"

{
h_turb_avg = 0.036 * k *(Re_L^0.8 - Re_cr^0.8) / (L - x_cr) "...finds h_turb_avg"
Q_turbulent = (h_turb_avg * (W * (L - x_cr)) * (T_s - T_inf)) "W ... heat tr from turb region of plate
considering only top surface of plate"

Q_tot = Q_lam + Q_turbulent

}

"If the entire boundary layer is turbulent:"

Nusselts_avg = 0.037 * Re_L^0.8 * Pr^(1/3) "....avg. Nusselts No."

h_avg * L / k = Nusselts_avg "...avg. heat tr coeff"

Q_turb_tot = h_avg * (L * W) * (T_s - T_inf) " total heat tr for the plate"

Results:

Thus:

(i) Total heat transfer to plate = Q_total = 7400 W … Ans.

(ii) Heat transfer from laminar portion of plate = Q_lam = 3102 W …. Ans.
(iii) Heat transfer from turbulent portion of plate = Q_turb = 4297 W …. Ans.
(iv) Heat transfer from plate, if there is turb. flow over the entire plate =
Q_tub_tot = 13157 W …. Ans.

------------------------------------------------------------------------------------------------------------
Plot the Q_total against the Air velocity U_inf:

Let Air velocity, U_inf vary from 28 m/s to 100 m/s. (At U_inf = 28 m/s, practically the entire plate
is in laminar flow).
Plot the Q_total against the plate temp, T_s:
Let T_s vary from 30 C to 300 C, keeping U_inf = 45 m/s:

Note that now, the film temp. T_f varies with each trial. But, since the properties of air are obtained
from the built I-in functions in EES, properties are evaluated at the correct T_f.
=====================================================================

C.2. Flow across cylinders and spheres:

"Prob. C.2.1. Assuming that a man can be represented by a cylinder 30 cm in diameter and 1.7 m high
with a surface temp of 30 C, calculate the heat he would lose while standing in a 36 km/h wind at 10 C.
[ VTU- Dec.06-Jan.07] "
 Ts

T inf
u inf
L

EES Solution:

"Data:"

D = 0.3 [m]
L = 1.7 [m]
u_inf = 10[m/s]
T_inf = 10[C]
T_s = 30[C]
P = 101300[Pa]

"Calculations:"

"This is a cylinder in cross flow. Use Churchill - Bernstein eqn."

T_f = (T_s + T_inf) / 2 "[C] ... film tem."

"Properties of air at T_f:"

Pr = Prandtl(Air,T=T_f)
rho = Density(Air,T=T_f,P=P) "[kg/m^3]"
mu = Viscosity(Air,T=T_f) "[kg/m-s]"
k=Conductivity(Air,T=T_f) "[W/m-C]"

Re_D = D * u_inf * rho / mu “….Reynolds No.”

“Churchill – Bernstein eqn:”

It is entered in EES:

Nusselt_cyl = 0.3 + (( 0.62 * Re_D^0.5 * Pr^(1/3)) / (1 + (0.4 / Pr)^(2/3))^(1/4)) * (1 +

(Re_D/282000)^(5/8))^(4/5) "...finds Nusselts No."

Nusselt_cyl = h * D / k "...finds heat tr. coeff. "

Q = h * ( pi * D * L) * (T_s - T_inf) "[W]... heat lost by man"

Results:
Thus:

Heat transfer coeff = h = 29.33 W/m^2.C … Ans.

Heat lost by man = Q = 939.8 W … Ans.

Plot Q against air velocity, U_inf:

It is easier to solve the above problem using the EES Procedure written earlier:

"Data:"

D = 0.3 [m]
L = 1.7 [m]
U_infinity = 10[m/s]
T_infinity = 10[C]
T_s = 30[C]
P_infinity = 101325[Pa]

CALL ForcedConv_Air_AcrossCylinder (P_infinity, T_infinity, U_infinity, L, D, T_s: Re_D,

Nusselt_D_bar, h_bar, Q)
------------------------------------------------
And, press F2 to get the Solution:
Main Solution:

Solution of PROCEDURE:

Thus, Q = 939.9 W, and h = 29.33 W/m^2.C …. Ans.

Of course, the results match with those obtained in Prob.2A1.2.1, as they should.
===============================================================
"Prob. C.2.2. Air stream at 27 C is moving at 0.3 m/s across 100 W incandescent bulb glowing at 127
C. If the bulb is approximated by a 60 mm dia sphere, estimate the heat transfer rate and percentage of
power lost due to convection. Use the correlation: Nu = 0.37. Re_D^0.6 [ VTU-Dec. 2010]”

D, T s

T inf
U inf

Fig.Prob.2A1.2.2

EES Solution:

"Data:"

D = 0.06[m]
T_s = 127[C]
T_inf = 27[C]
U_inf = 0.3[m/s]
T_f = (T_s+T_inf)/2 "[C]... mean film temp."

"Properties of Air:"

mu=Viscosity(Air,T=T_f) "[kg/m-s]"
rho=Density(Air,T=T_f,P=1.013e05) "[kg/m^3]"
nu = mu/rho "[m^2/s]"
cp=Cp(Air,T=T_f) "[J/kg-C]"
k=Conductivity(Air,T=T_f) "[W/m-C]"
Pr = mu*cp/k

"Calculations:"

Re_D = D*U_inf*rho/mu "finds Reynolds No., Re_D"

Nusselt = 0.37 * Re_D^0.6 "finds Nusselts No."
Nusselt = h*D/k "finds h"
Q_conv = h*(pi * D^2) * (T_s-T_inf) "W"
Q = 100[W] "...by data"
percent_conv = (Q_conv/Q) * 100

Results:
Thus:

Heat transfer by convection = Q_conv = 11.87 W …. Ans.

Percentage of heat lost by convection = 11.87% …. Ans.

----------------------------------------------------------------------------------------------------------------------

And, if we use the more accurate Whitaker’s relation, viz.

We get:

Note that now the Q_conv = 8.809 W.

====================================================================
"Prob. C.2.3. A 25 mm dia high tension line has an electrical resistance of 10^-4 Ohm/m and is
transmitting a current of 1000 A. If the ambient air is at 10 C, and is flowing at 5 m/s, what is the surface
temp?
Plot the variation of surface temp for air velocities varying from 1 m/s to 10 m/s"

Ts Dia = D

T inf
U inf
L

EES Solution:

"Data:"

D = 0.025[m]
L = 1 [l]
R_e = 1E-04 [Ohm/m]
I = 1000 [A]
{T_s = 127[C]}
T_inf = 10[C]
U_inf = 5[m/s]
T_f = (T_s+T_inf)/2 "[C]... mean film temp."

"Properties of Air:"

mu=Viscosity(Air,T=T_f) "[kg/m-s]"
rho=Density(Air,T=T_f,P=1.013e05) "[kg/m^3]"
nu = mu/rho "[m^2/s]"
cp=Cp(Air,T=T_f) "[J/kg-C]"
k=Conductivity(Air,T=T_f) "[W/m-C]"
Pr = mu*cp/k

"Calculations:"

Re_D = D * U_inf * rho / mu "finds Reynolds No., Re_D"

"This is a cylinder in cross flow. Use Churchill - Bernstein eqn."

Nusselt_cyl = 0.3 + (( 0.62 * Re_D^0.5 * Pr^(1/3)) / (1 + (0.4 / Pr)^(2/3))^(1/4)) * (1 +

(Re_D/282000)^(5/8))^(4/5) "...finds Nusselts No."

Nusselt_cyl = h * D / k "finds h"

Q_conv = h * (pi * D * L) * (T_s-T_inf) "W"
Q_joule = I^2 * (R_e * L ) "[W] ...Joule heating ..by data"
Q_joule = Q_conv "...by heat balance"

Results:
Thus:

Surface temp of high tension line = T_s = 36.01 C … Ans.

To plot T_s against wind velocity, U_inf:

To plot T_s against wind temp, T_inf, with U_inf = 5 m/s:
Note: EES is ideally suited to do these calculations since as ambient temp T_inf changes, T_f will also
change and in each trial properties of air are calculated at the corresponding T_f by the built-in functions
of EES.

$UnitSystem SI C Pa J

"Prob. C.2.4. Consider a 100 W incandescent lamp of 10cm dia spherical shape, with a surface emissivity
of 0.85. It is subjected to an air stream at 20 C, flowing at a velocity of 2 m/s. What will be the glass
surface temp?
Plot the graph of surface temp against air velocities from 0.5 m/s to 5 m/s."

T s,  Dia = D

T inf
U inf

EES Solution:

"Data:"

D = 0.1[m]
{T_s = 127[C]}
T_inf = 20[C]
U_inf = 2[m/s]
epsilon = 0.85 "...emissivity"
sigma = 5.67e-08 [w/m^2-K^4]"....Stefan - Boltzmann const."
T_f = (T_s+T_inf)/2 "[C]... mean film temp."

"Properties of Air:"

mu_inf=Viscosity(Air,T=T_inf) "[kg/m-s]"
mu_s=Viscosity(Air,T=T_s) "[kg/m-s]"

rho_inf=Density(Air,T=T_inf,P=1.013e05) "[kg/m^3]"
nu_inf = mu_inf/rho_inf "[m^2/s]"
cp_inf=Cp(Air,T=T_inf) "[J/kg-C]"
k_inf=Conductivity(Air,T=T_inf) "[W/m-C]"
Pr = mu_inf*cp_inf/k_inf
Q = 100 [W]

"Calculations:"

Re_D = D * U_inf * rho_inf / mu_inf "finds Reynolds No., Re_D"

"This is a sphere in cross flow. Use Whitaker eqn.

Here, fluid prop. are taken at free stream temp T_inf except for mu_s which is evaluated at surface temp
T_s.
Valid for 3.5 < Re_D < 80000 and 0.7 < Pr < 380"

Nusselt_sph = 2 + ( 0.4 * Re_D^0.5 + 0.06 * Re_D^(2/3)) * Pr^0.4 * (mu_inf / mu_s)^(1/4) "...finds

Nusselts No."

Nusselt_sph = h * D / k_inf "finds h"

Q_conv = h * (pi * D^2) * (T_s-T_inf) "W"
Q_rad = sigma * epsilon * (pi * d^2) * ((T_s + 273)^4 - (T_inf + 273)^4) "[W] ...radition heat transfer ."
Q = Q_conv + Q_rad "...by heat balance"

Results:

Thus:

The glass surface temp = T_s = 143.1 C … Ans.

-----------------------------------------------------------------------------------------------------------------

Plot T_s vs Air velocity, U_inf:

----------------------------------------------------------------------------------------------
Plot T_s vs Ambient temp, T_inf:
Prob.C.2.5. A long, 8 cm dia steam pipe has its external temp as 90 C and is passing through a room
where the air is at 7 C and blowing at 50 km/h. Determine the rate of heat loss per unit length of pipe.
Ts

T inf
U inf
L

Dia = D

EES Solution:

Here, this is the case of cross flow across a cylinder. We use the Churchill- Bernstein eqn.

Now, it is convenient to use the EES Procedure written earlier:

"Data:"

P_infinity = 1.01325E05 [Pa]

T_infinity = 7 [C]
U_infinity = 50 * convert(km/h,m/s) "[m/s] ...air velocity"
L = 1 [m]
D = 0.08 [m]
T_s = 90 [C]

CALL ForcedConv_Air_AcrossCylinder (P_infinity, T_infinity, U_infinity, L, D, T_s: Re_D,

Nusselt_D_bar, h_bar, Q)
Now, simply press F2 and the solution appears in two windows: one, results of Main program, and the
second, results of PROCEDURE:

See the Results below:

Results of Main program:

And, Results of PROCEDURE:

Thus, Q = 1130 W, with h_bar = 54.19 W/m^2.C … Ans.

Note that EES program is very useful when complicated eqns are involved, and, particularly when many
property values have to be determined since EES has built-in Functions for properties of many
substances.
Prob.C.2.6. A copper sphere, 10 mm dia, and at 75 C is subjected to an air stream at 1 atm and 25 with a
velocity of 10 m/s. Estimate the initial heat transfer rate and the heat transfer coeff.
Ts

T inf
U inf

EES Solution:
Once again, let us use the PROCEDURE to find h and Q for the case of a sphere in cross flow of air using
Whitaker eqn:

“Data:”

D = 0.01[m]
T_s = 75[C]
T_infinity = 25[C]
P_infinity = 1.01325e05[Pa]
U_infinity = 10[m/s]

Calling the Procedure:

CALL FC_Air_AcrossSphere_Whitaker (P_infinity, T_infinity, U_infinity, D, T_s: Re_D, Nusselt_D_bar,

h_bar, Q)

Now, press F2 and the Results are presented in two windows, one for Main program and the other,
for the PROCEDURE:

We get:

And, Results in PROCEDURE window:

Thus: Q = 1.888 W, and h = 120.2 W/m^2.C …. Ans.

C.3. Flow across Tube banks:

Data from Ref.[2]:

"Prob. C.3.1. A pre-heater for air has surface temp of tubes at 100 C and in the tube bank there are a total
of 196 tubes arranged in a square, aligned array. Tube dia = 10 mm, 1 m long and S_T = S_L = 15 mm.
Air enters at 1 atm, 25 C and at 5 m/s. What is the total rate of heat transfer to air? Also, find the pressure
drop."

SL
Ts
D
ST
U
Ti

Transverse row: 1 2 3 4

"EES Solution:"

It is convenient to solve the problem with EES since the properties of air are available in EES as built-in
functions.

We shall use the EES Procedures written earlier."

"Data:"

T_s = 100 [C]

T_i = 25 [C]
{T_o = 70 [C] ".... assumed. Will be commented out later"}
U = 5 [m/s]
D = 0.01 [m]
L = 1 [m]
S_T = 0.015 [m]
S_L = 0.015 [m]
N_L = 14
N_T = 14
P = 1e05 [Pa]

"In-Line tube arrangement:"

"Calculations:"

T_f = (T_i + T_o) / 2 "..avg temp of air in the array"

"Properties of Air at T_f:"

rho=Density(Air,T=T_f,P=P) "[kg/m^3]"
rho_in = Density(Air,T=T_i,P=P) "[kg/m^3]"
cp=Cp(Air,T=T_f) "[J/kg-C]"
k=Conductivity(Air,T=T_f) "[W/m-K]"
mu=Viscosity(Air,T=T_f) "[kg/m-s]"
Pr=Prandtl(Air,T=T_f)"[-]"
Pr_s=Prandtl(Air,T=T_s)"[-]"
mu_s=Viscosity(Air,T=T_s) "[kg/m-s]"

"For In-Line arrangement:"

U_max = (S_T / (S_T - D)) * U "[m/s] .... max. velocity"

Re_D = U_max * D * rho / mu "...Reynolds No."

"Therefore: Nusselts No.:"

Nusselt_D = NUSSELT_TubeBank_In_line(Re_D, Pr, Pr_s)

"Note: No correction factor to Nusselts No. since N_L = 14"

"Therefore: heat transfer coeff.:"

h = Nusselt_D * k / D "..[W/m^2-K] ... heat tr. coeff."

Outlet temp. of Air:

Enter it in EES:

(T_s - T_o) / (T_s - T_i) = exp(- h * (pi * D * L * N_T * N_L) / (Mass_flow * cp)) " ... determines air outlet
temp, T_o"
"Therefore: heat transferred:"

"Q is equal to heat gained by the air while passing through the array of tubes"

Mass_flow = rho_in * U * (N_T * S_T * L) "[kg/s]...mass flow rate through the array"

"And:"

Q = Mass_flow * cp * (T_o - T_i) "[W] ... heat gained by air in the array"

"Pressure drop:[Ref:1]”

Friction factor for In-line arrangement is given by:

i.e. in EES it is entered as:

ff = (0.044 + (0.08 * (S_L / D)) / ((S_T - D)/D)^(0.43 + 1.13 * D/S_L))*Re_D^(-0.15) "...friction factor"

G_max = rho * U_max "[kg/s-m^2] ... mass velocity"

DELTAP = (2 * ff *G_max^2 * N_L / rho_in) * (mu_s / mu)^0.14 "[N/m^2] ... pressure drop"

Results:
Thus:

Exit temp. of Air = T_o = 71.44 C …Ans.

Heat transfer Q = 57311 W …. Ans.

Pressure drop DELTAP = 525.9 N/m^2 … Ans.

----------------------------------------------------------------------------
Plot the variation of exit temp of air (T_o) and heat transferred (Q) as Air velocity U varies
from 1 to 10 m/s:
"Prob. C.3.2. A tube bank has surface temp of tubes at 90 C and the tube bank has 6 rows of tubes, each
stack 40 tubes high, in an in-line arrangement. Tube dia = 6.33 mm mm, 1 m long and S_T = S_L = 1.9
cm. Air enters at 1 atm, 20 C and 4.5 m/s/. What is the total rate of heat transfer to air? Also, find the
pressure drop."

SL
Ts
D
ST
U
Ti

Transverse row: 1 2 3 4

"EES Solution:"

"This problem is similar to the previous problem. See the EES Functions written earlier for Nusselts No.
and Correction factors for N_L < 14”
"Data:"

T_s = 90 [C]
T_i = 20 [C]
{T_o = 70 [C] ".... assumed. Will be commented out later"}
U = 4.5 [m/s]
D = 0.00633 [m]
L = 1 [m]
S_T = 0.019 [m]
S_L = 0.019 [m]
N_L = 6
N_T = 40
P = 1e05 [Pa]

"In-Line tube arrangement:"

"Calculations:"

T_f = (T_i + T_o) / 2 "..avg temp of air in the array"

"Properties of Air at T_f:"

rho=Density(Air,T=T_f,P=P) "[kg/m^3]"
rho_in = Density(Air,T=T_i,P=P) "[kg/m^3]"
cp=Cp(Air,T=T_f) "[J/kg-C]"
k=Conductivity(Air,T=T_f) "[W/m-K]"
mu=Viscosity(Air,T=T_f) "[kg/m-s]"
Pr=Prandtl(Air,T=T_f)"[-]"
Pr_s=Prandtl(Air,T=T_s)"[-]"
mu_s=Viscosity(Air,T=T_s) "[kg/m-s]"

"For In-Line arrangement:"

U_max = (S_T / (S_T - D)) * U "[m/s] .... max. velocity"

Re_D = U_max * D * rho / mu "...Reynolds No."

"Note: Correction factor to Nusselts No. has to be used since N_L =<14"

"This correction factor is obtained from the Table supplied in Text Books (ex. [2]), converted here into a
EES curve fit eqn for convenience"

F = F_InLine (N_L) "...correction factor since there are less than 14 rows"

"Therefore: Nusselts No. (corrected):"

Nusselt_D = F * NUSSELT_TubeBank_In_line(Re_D, Pr, Pr_s)

"Therefore: heat transfer coeff.:"

h = Nusselt_D * k / D "..[W/m^2-K] ... heat tr. coeff."

(T_s - T_o) / (T_s - T_i) = exp(- h * (pi * D * L * N_T * N_L) / (Mass_flow * cp)) " ... determines air outlet
temp, T_o"
"Therefore: heat transferred:"

"Q is also equal to heat gained by the air while passing through the array of tubes"

Mass_flow = rho_in * U * (N_T * S_T * L) "[kg/s]...mass flow rate through the array"

"And:"

Q = Mass_flow * cp * (T_o - T_i) "[W] ... heat gained by air in the array"

"Pressure drop:[Ref:1]”

ff = (0.044 + (0.08 * (S_L / D)) / ((S_T - D)/D)^(0.43 + 1.13 * D/S_L))*Re_D^(-0.15) "...friction factor"

G_max = rho * U_max "[kg/s-m^2] ... mass velocity"

DELTAP = (2 * ff *G_max^2 * N_L / rho_in) * (mu_s / mu)^0.14 "[N/m^2] ... pressure drop"

Results:

Thus:

Air exit temp. = T_o = 30.15 C… Ans.

Heat transferred = Q = 41452 W … Ans.
Pressure drop = DELTAP = 35.48 N/m^2 …. Ans.
--------------------------------------------------------------------------
Plot the variation of heat transferred (Q) and pressure drop DELTAP as Air velocity U
varies from 1 to 10 m/s:
C.4. Flow inside tubes and ducts:

"Prob. C.4.1. Water at a velocity of 1.5 m/s enters a 2 cm dia heat exchanger tube at 40 C. The heat
exchanger tube wall is maintained at a temp of 100 C. If the water is heated to a temp of 80 C, find the
length of the length of the exchanger tube required. - [VTU-Dec.09-Jan.2010]”

EES Solution:

This is a very common type of problem, often asked in the University exams.

Let us use the PROCEDURE in EES, already written.

---------------------------------------------------------------------------------------------------------------

Fluid$ = 'Water'
T_in = 40[C]
T_out= 80[C]
T_s = 100[C]

D = 0.02[m]
U = 1.5[m/s]

CALL FC_Inside_Cyl(Fluid$, T_s, T_in, T_out, D,U : Re_D, Nusselt, h,Q, LMTD, L, f, DELTAP )

“---------------------------------------------------------------------------------“

Now, press F2, and the results appear:

Main Results:
PROCEDURE Results:

Thus:

L = 4.25 m … Length of heat exchanger tube required…. Ans.

ΔP = 4672 N/m^2 … Pressure drop over length L …. Ans.

In addition, plot the variation of Length and DELTAP as the velocity changes:
Take the range for U as 0.5 to 5.5 m/s:
Plot Length against Velocity:

Plot pressure drop against Velocity:

"Prob.C.4.2. Engine Oil is heated by flowing through a circular tube of diameter d = 50 mm and length L
= 25 m and whose surface is maintained at 150 C. (a) If the flow rate and inlet temp of oil are 0.5 kg/s and
20 C, what is the outlet temp and total heat transfer rate for the tube?
(b) For flow rates in the range 0.5 < m_dot < 2.0 kg/s, compute and plot the variation of outlet temp,
T_out and Q with m_dot. For what flow rate(s) are Q and T_out maximized?"
EES Solution:

First, let us write functions for properties of Engine Oil.

They can be used subsequently to solve all problems where properties of Engine oil are required.

Properties of Engine oil are taken from Ref.[2], and the curve – fit equations were obtained using
CurveExpert software.

----------------------------------------------------------------------------------------------------------------------------------

"Functions for properties of Engine Oil in the Temp range: 0 to 150 C.

Ref: Data from HMT by Cengel, 3rd Ed."

Density of Engine oil:

CurveExpert Curve fit:

Linear Fit: y=a+bx
r = 0.9999382
Coefficient Data:
a= 899.47228
b= -0.59190217

Density vs Temp for Engine Oil

.00
900

.00
Density (kg/m^3)

880

.00
860

.00
840

.00
820

.00
800 0.0 20.0 40.0 60.0 80.0 100.0 120.0 140.0 160.0

Temp. (C)
Sp. Heat of Engine Oil:

Curve-fit from Excel:

-------------------------------------------------------------------------------------------------------

Th. cond. of Engine Oil:

Curve fit from CurvreExpert:

k vs T for Engine oil

50
0.1
4 8
0.1
46
0.1
44
0.1
k (W/m.K)

42
0.1
4 0
0.1
38
0.1
36
0.1
34
0.1
3 2
0.1
30
0.1 0.0 20.0 40.0 60.0 80.0 100.0 120.0 140.0

T (deg.C)

-----------------------------------------------------------------------------------------------
Dyn. viscosity of Engine Oil:

For better accuracy, curve fit equations are obtained in two temp. ranges, viz. from 0 to 80 deg.C
and from 81 to 150 deg.C:

Curve fit from CurvreExpert:

In the range 0 to 80 deg. C:

And, in the range 81 to 150 deg. C:

========================================================

EES Functions:

Function rho_EngineOil(T)

{ rho_EngineOil
This function returns the density (kg/m^3) of Engine oil as a function of Temp (deg.C) in the range: 0 -
150 C
}

If (T < 0) OR (T > 150) Then

CALL error('T must be between 0 and 150 deg. C !!')
EndIf
rho_EngineOil := 899.47228 - 0.59190217 * T
End

"--------------------------------------------------------------------------"

Function cp_EngineOil(T)

{cp_EngineOil
This function returns the sp. heat (J/kg.C) of Engine oil as a function of Temp (deg.C) in the range: 0 -
150 C
}

If (T < 0) OR (T > 150) Then

CALL error('T must be between 0 and 150 deg. C !!')
EndIf
cp_EngineOil := 4.2896 * T + 1793.378
End

"-----------------------------------------------------------------------"
Function k_EngineOil(T)

{k_EngineOil
This function returns the Th. cond. (W/m.C)) of Engine oil as a function of Temp (deg.C) in the range: 0 -
150 C
}

If (T < 0) OR (T > 150) Then

CALL error('T must be between 0 and 150 deg. C !!')
EndIf
k_EngineOil := 0.14687508 - 0.00030494 * T + 2.03E-05 * T^2 - 6.07E-07 * T^3 + 7.77E-09 * T^4 -
4.51E-11 * T^5 + 9.79E-14 * T^6
End

"--------------------------------------------------------------------------------"

Function mu_EngineOil(T)

{mu_EngineOil
This function returns the Dyn. visc. (N.s/m^2)) of Engine oil as a function of Temp (deg.C) in the range: 0
- 150 C
}

If (T < 0) OR (T > 150) Then

CALL error('T must be between 0 and 150 deg. C !!')
EndIf
If (T >= 0) And (T <=80) Then
mu_EngineOil := (3.813999 - 0.03144 * T) / (1 + 0.010332 * T + 0.006492 * T^2)
Else
If (T > 80 ) And (T <= 150) Then
mu_EngineOil := 3398.48 * 0.997603^T * T^(-2.59511)
EndIf
EndIf
End

"--------------------------------------------------------------------------------"
Function Pr_EngineOil(T)

{Pr_EngineOil
This function returns the Prandtl No. (= cp . mu /k) of Engine oil as a function of Temp (deg.C) in the
range: 0 - 150 C
}

If (T < 0) OR (T > 150) Then

CALL error('T must be between 0 and 150 deg. C !!')
EndIf
Pr_EngineOil := cp_EngineOil(T) * mu_EngineOil(T) / k_EngineOil(T)
End

"--------------------------------------------------------------------------------"

And now, for the Solution of the problem:

"Data:"

T_in = 20[C]
{T_out= 140[C]"..assumed...will be commented out later"}
T_s = 150[C]
T_b = (T_in + T_out)/2
d = 0.05[m]
L = 25[m]
m_dot = 0.5[kg/s]

"Properties of Engine oil at bulk mean temp, T_b:"

k=k_EngineOil(T_b) "[W/m-C]"

rho= rho_EngineOil(T_b) "[kg/m^3]"

mu= mu_EngineOil(T_b) "[kg/m-s]"

cp= cp_EngineOil(T_b) "[J/kg-C]"

Pr= Pr_EngineOil(T_b)

"Calculations:"

A = pi * d^2 / 4 "[m^2]... area of cross-section"

G = m_dot / A "[kg/s-m^2]"
Re = G * d /mu "Reynold's No."

"We get Re = 425.2 which is less than 2300; Therefore, flow is Laminar."

"Now, Thermal entry length L_t is given by:"

L_t = .05 * Re * Pr * d "[m] ... thermal entry length"

"We get L_t = 493.6 m, which is much greater than the tube length of 25 m.
Therefore, the thermally boundary layer is still developing.
This is generally the case for high Prandtl No. fluids."
" Now, Nu = 3.66 for Laminar flow when the velocity and thermal boundary layers are fully developed.
In the present case, since the thermal boundary layer is still not fully developed, we use:"
In EES, it is entered:

Nusselt = 3.66 + (0.065 * (d/L) * Re * Pr) / (1 + 0.04 * ((D / L) * Re * Pr)^(2/3)) "....Nusselts No."

"Therefore: heat transfer coeff. h:"

Nusselt = h * d / k "[W/m^2-C]...finds h"

"Now:"
A_s = pi * d * L "[m^2]...surface area"

"Heat transfer, Q:"

Q = m_dot * cp * (T_out - T_in) "[W]"

AMTD = ((T_s - T_out) + (T_s - T_in))/ 2

“Note: For use in Newton’s eqn to calculate Q, we should strictly use LMTD. However, we have used here
Arithmetic Mean Temp Diff (AMTD) = average of temp diff at the inlet and outlet of oil. We shall show later
that values of LMTD and AMTD are practically the same.”

"Now, Q is also equal to:"

Q = h * A_s * AMTD

"Pressure drop:"

U = G / rho "[m/s] .... mean velocity"

f = 64/Re "...friction factor for Laminar flow"

DELTAP = f * ( L / d) * U^2 / 2 * rho "[N/m^2] ... pressure drop"

"Check:"

LMTD = ((T_s - T_out) - (T_s - T_in)) / ln ((T_s - T_out) / (T_s - T_in))

Results:
Thus:

Oil outlet temp = T_out = 36.12 C …. Ans.

Heat transferred = Q = 15422 W … Ans.

Pressure drop DELTAP = 42276 Pa … Ans.

Note that AMTD = 121.9 C and LMTD = 121.8 C. i.e. they are practically the same.
--------------------------------------------------------------------------------------------------------

To plot T_out and Q against m_dot:

Note that flow is laminar for the entire range of mass flow rate.
T_out vs m_dot:

Note that T_out is maximum for minimum flow rate, i.e. for 0.5 kg/s.

Q vs m_dot:

Note that heat transfer, Q , goes on increasing with increasing flow rate.

=======================================================================
"Prob. C.4.3. Water flows at 2 kg/s through a 40 mm dia tube 4 m long. The water enters the tube at 25
C, and the surface temp is 90 C.
(a) What is the outlet temp of water? What is the rate of heat transfer to water?
(b) Maintaining the outlet temp found in part (a), plot the tube length required as a function of tube
surface temp when the surface temp varies from 85 to 95 C. All other conditions remain the same.
[Ref. 3]"

EES Solution:

"Data:"

T_in = 25[C]
T_s = 90[C]
d = 0.04[m]
L = 4 [m]
m_dot = 2 [kg/s]

"Calculations:"

{T_out= 80[C]"...assumed .... will be commented out later"}

A_c = pi * d^2 / 4 "[m^2] .... area of cross-section"

T_b = (T_in + T_out)/2 "[C]....bulk mean temp of water"

"Properties of Water at bulk mean temp, T_b:"

k=Conductivity(Water,T=T_b,P=1.013e05)
rho=Density(Water,T=T_b,P=1.013e05)
mu=Viscosity(Water,T=T_b,P=1.013e05)
cp=SpecHeat(Water,T=T_b,P=1.013e05)
Pr=Prandtl(Water,T=T_b,P=1.013e05)

G = m_dot / A_c "[kg/s-m^2] ... mass velocity"

Re = G * d /mu "finds Re > 10,000"

“Therefore: apply Dittus Boelter eqn.:”

Nusselt = 0.023 * Re^0.8 * Pr^0.4 "finds Nusselts No. for Re > 10000"
Nusselt = h * d / k "finds h"

DELTAT_in = T_s - T_in

DELTAT_out = T_s - T_out

LMTD = (DELTAT_in - DELTAT_out) / ln(DELTAT_in/DELTAT_out)

Q = h * (pi * d * L) * LMTD "finds Q"
Q = m_dot * cp * (T_out - T_in) "finds T_out"

"Also, find the pressure drop:"

"Friction factor: Use the first Petukhov eqn, which is an explicit eqn. for f. Re range: 3000 to 5E06"

f = (0.79 * ln(Re) - 1.64)^(-2)

DELTAP = f * (L / d) * rho * (G/rho)^2 / 2 "[N/m^2]… Pressure drop"

Results:

Thus:

T_out = 44.72 C …. Outlet temp of water …. Ans.

Q = 164989 W … heat transfer to water … Ans.

DELTAP = 2354 N/m^2 ….. Pressure drop …. Ans.

-----------------------------------------------------------------------

Plot L against various values of T_s, keeping T_out = 44.72 C:

Plot of L vs T_s:

Plot of DELTAP vs T_s:

"Prob.C.4.4. Unused engine oil with a 100 C inlet temp flows at a rate of 250 g/s through a 5.1 cm ID
pipe that is enclosed by a jacket containing condensing steam at 150 C. If the pipe is 9 m long, determine
the outlet temp of oil [Ref. 5]"

EES Solution:

EES Functions for properties of Engine oil are already written..

"Data:"

T_in = 100[C]
{T_out= 140[C]"..assumed...will be commented out later"}
T_s = 150[C]
T_b = (T_in + T_out)/2
d = 0.051[m]
L = 9[m]
m_dot = 0.25[kg/s]

"Properties of Engine oil at bulk mean temp, T_b:"

k=k_EngineOil(T_b) "[W/m-C]"

rho= rho_EngineOil(T_b) "[kg/m^3]"

mu= mu_EngineOil(T_b) "[kg/m-s]"

cp= cp_EngineOil(T_b) "[J/kg-C]"

Pr= Pr_EngineOil(T_b)

"Calculations:"

A = pi * d^2 / 4 "[m^2]... area of cross-section"

G = m_dot / A "[kg/s-m^2]"
Re = G * d /mu "Reynold's No."

"We get Re = 609.2 which is less than 2300; Therefore, flow is Laminar."

"Now, Thermal entry length L_t is given by:"

L_t = .05 * Re * Pr * d "[m] ... thermal entry length"

"We get L_t = 272.1 m, which is much greater than the tube length of 9 m.

Therefore, the thermally boundary layer is still developing.

This is generally the case for high Prandtl No. fluids."

" Now, Nu = 3.66 for Laminar flow when the velocity and thermal boundary layers are fully developed.

In the present case, since the thermal boundary layer is still not fully developed, and the variation of
viscosity of engine oil with temp is significant, we use:"

mu_s= mu_EngineOil(T_s) "[kg/m-s] …. Viscosity of engine oil at wall temp."

Nusselt = 1.86 * (Re * Pr * d / L)^(1/3) * (mu / mu_s)^0.14 "....Nusselts No."

"Therefore: heat transfer coeff. h:"

Nusselt = h * d / k "[W/m^2-C]...finds h"

"Now:"

A_s = pi * d * L "[m^2]...surface area"

"Heat transfer, Q:"

Q = m_dot * cp * (T_out - T_in) "[W]"

AMTD = ((T_s - T_out) + (T_s - T_in))/ 2 “…Arithmetic Mean Temp Difference”

"Now, Q is also equal to:"

Q = h * A_s * AMTD

“Simultaneous solution of above two eqns for Q gives the value of T_out”

"Pressure drop:"

U = G / rho "[m/s] .... mean velocity"

f = 64 / Re "...friction factor for Laminar flow"

DELTAP = f * ( L / d) * U^2 / 2 * rho "[N/m^2] ... pressure drop"

"Check:"

LMTD = ((T_s - T_out) - (T_s - T_in)) / ln ((T_s - T_out) / (T_s - T_in))

Results:
Thus:

T_out = 105.9 C …. Ans.

Q = 3275 W …. Ans.

And, also note that by taking AMTD instead of LMTD, there is no significant error, since AMTD =
47.07 C and LMTD = 47.01 C, almost equal to AMTD.

----------------------------------------------------------------------------------------

Now, if the flow rate varies from 0.1 to 0.6 kg/s, plot the variation of T_out and Q, all other
parameters remaining the same:
========================================================
"Prob. C.4.5. The velocity of water flowing through a tube of 2.2 cm dia is 2 m/s. Steam condensing at
150 C on the outside surface of the tube heats the water from 15 C to 60 C over the length of the tube.
Find the heat transfer coeff and the length of the tube neglecting the tube and steam side film resistance. -
[VTU-June.2012]"

EES Solution:

Let us use the EES PROCEDURE written earlier:

Data:

Fluid$ = 'Water'

T_in = 15[C]
T_out= 60[C]
T_s = 150[C]

D = 0.022[m]

U = 2 "[m/s]"

CALL FC_Inside_Cyl(Fluid$, T_s, T_in, T_out, D,U : Re_D, Nusselt, h,Q, LMTD, L, f, DELTAP )

----------------------------------------------------------------------------------------------------------------------
Now, press F2 to get the solution. We get:

Results: Main:

Results: PROCEDURE:

Thus:
Heat transfer coeff. = h = 8298 W/m^2.C …. Ans.

Length of tube = L = 2.233 m … Ans.

Pressure drop = DELTAP = 3999 N/m^2 … Ans.

---------------------------------------------------------------------------------------------

Plot L and DELTAP against velocity, U_inf:

==========================================================================

"Prob. C.4.6. Consider the flow of water at a rate of 0.015 kg/s through a square duct 2 cm x 2 cm whose
walls are maintained at a uniform temp of 100 C. Assuming that the flow is hydrodynamically and
thermally developed, determine the length of the duct required to heat water from 30 C to 70 C. [VTU-
Jan./Feb.2006]"

EES Solution:

"Data:"

T_in = 30[C]
T_out= 70[C]
T_s = 100[C]
T_b = (T_in + T_out)/2
W = 0.02[m]
A_c = W^2 "[m^2]"
m_dot = 0.015 [kg/s]

"Properties of Water at bulk mean temp, T_b:"

k=Conductivity(Water,T=T_b,P=1.013e05)
rho=Density(Water,T=T_b,P=1.013e05)
mu=Viscosity(Water,T=T_b,P=1.013e05)
cp=SpecHeat(Water,T=T_b,P=1.013e05)
Pr=Prandtl(Water,T=T_b,P=1.013e05)

"Calculations:"

G = m_dot / A_c "[kg/s-m^2]... mass velocity"

m_dot = rho * A_c * U_inf "....finds velocity, U_inf"
P = (W + W ) * 2 "[m] .... perimeter"
D_h = 4 * A_c / P "[m] ... hydraulic dia of duct"
Re = D_h * G / mu "finds Re = 1371 < 2300 .... Laminar flow"

Nusselt = 3.66 " Nusselts No. for Re < 2300 and fully developed flow"

Nusselt = h * D_h / k "finds h"

DELTAT_in = T_s - T_in

DELTAT_out = T_s - T_out
LMTD = (DELTAT_in - DELTAT_out) / ln(DELTAT_in/DELTAT_out)
Q = m_dot * cp * (T_out - T_in) "finds Q, W"
Q = h * (P * L) * LMTD "finds L"

"Also, find the pressure drop:"

"Friction factor: For laminar flow inside tubes: f = 56.92 / Re, for square section:"

f = 56.92 / Re

DELTAP = f * (L / D_h) * rho * U_inf^2 / 2 "[N/m^2]"

Results:

Thus: L = 5.758 m …. Length of tube required…Ans.

DELTAP = 8.506 N/m^2 …. Ans.